If a model has more than one endogenous variable, several facts need to be considered in the choice of an estimation method. If the model has endogenous regressors, then an instrumental variables method such as 2SLS or 3SLS can be used to avoid simultaneous equation bias. Instrumental variables must be provided to use these methods. A discussion of possible choices for instrumental variables is provided in the section Choice of Instruments in this chapter.
The following is an example of the use of 2SLS and the INSTRUMENTS statement:
proc model data=test2;
exogenous x1 x2;
parms a1 a2 b2 2.5 c2 55 d1;
y1 = a1 * y2 + b2 * x1 * x1 + d1;
y2 = a2 * y1 + b2 * x2 * x2 + c2 / x2 + d1;
fit y1 y2 / 2sls;
instruments b2 c2 _exog_;
run;
The estimation method selected is added after the slash (/) on the FIT statement. The INSTRUMENTS statement follows the FIT statement and in this case selects all the exogenous variables as instruments with the _EXOG_ keyword. The parameters B2 and C2 in the instruments list request that the derivatives with respect to B2 and C2 be additional instruments.
Full information maximum likelihood (FIML) can also be used to avoid simultaneous equation bias. FIML is computationally more expensive than an instrumental variables method and assumes that the errors are normally distributed. On the other hand, FIML does not require the specification of instruments. FIML is selected with the FIML option on the FIT statement.
The preceding example is estimated with FIML by using the following statements:
proc model data=test2;
exogenous x1 x2;
parms a1 a2 b2 2.5 c2 55 d1;
y1 = a1 * y2 + b2 * x1 * x1 + d1;
y2 = a2 * y1 + b2 * x2 * x2 + c2 / x2 + d1;
fit y1 y2 / fiml;
run;