FOPTNAME Function

Returns the name of an item of information about a file.

Category:	External Files
See:	FOPTNAME Function: Windows in SAS Companion for Windows
	FOPTNAME Function: UNIX in SAS Companion for UNIX Environments
	FOPTNAME Function: z/OS in SAS Companion for z/OS

Syntax

FOPTNAME(file-id,nval)

Required Arguments

file-id

is a numeric variable that specifies the identifier that was assigned when the file was opened, generally by the FOPEN function.

nval

is a numeric constant, variable, or expression that specifies the number of the information item.

Details

FOPTNAME returns a blank if an error occurred.

Windows Specifics: The number, value, and type of information items that are available depend on the operating environment and access method.

Examples

Example 1: Retrieving File Information Items and Writing Them to the Log

This example retrieves the system-dependent file information items that are available and writes them to the log:

%let filrf=myfile;
%let rc=%sysfunc(filename(filrf,
   physical-filename));
%let fid=%sysfunc(fopen(&filrf));
%let infonum=%sysfunc(foptnum(&fid));
%do j=1 %to &infonum;
   %let name=%sysfunc(foptname(&fid,&j));
   %let value=%sysfunc(finfo(&fid,&name));
   %put File attribute &name equals &value;
%end;
%let rc=%sysfunc(fclose(&fid));
%let rc=%sysfunc(filename(filrf));

Example 2: Creating a Data Set with Names and Values of File Attributes

This example creates a data set that contains the name and value of the available file attributes:

data fileatt;
   length name $ 20 value $ 40;
   drop rc fid j infonum;
   rc=filename("myfile","physical-filename");
   fid=fopen("myfile");
   infonum=foptnum(fid);
   do j=1 to infonum;
      name=foptname(fid,j);
      value=finfo(fid,name);
      put 'File attribute ' name 
       'has a value of ' value;
      output;
   end;
   rc=filename("myfile");
run;