If you omit the arguments, the DATA step automatically names each successive data set that you create as DATAn, where n is the smallest integer that makes the name unique.

Arguments

data-set-name: names the SAS data file or DATA step view that the DATA step creates. To create a DATA step view, you must specify at least one data-set-name and that data-set-name must match view-name.

Restriction:data-set-name must conform to the rules for SAS names, and additional restrictions might be imposed by your operating environment.

Tips:Instead of using a data set name, you can specify the physical pathname to the file, using syntax that your operating system understands. The pathname must be enclosed in single or double quotation marks.

You can execute a DATA step without creating a SAS data set. See Creating a Custom Report. For more information, see When Not Creating a Data Set (Form 2) .

See:For more information about the types of SAS data set names and when to use each type, see Names in the SAS Language in SAS Language Reference: Concepts.

(data-set-options): specifies optional arguments that the DATA step applies when it writes observations to the output data set.

See:SAS Data Set Options: Reference for a definition and list of data set options.

Example:Creating Multiple Data Files and Using Data Set Options

/ DEBUG: enables you to debug your program interactively by helping identify logic errors, and sometimes data errors.

/ NESTING: specifies that a note will be printed to the SAS log for the beginning and end of each DO-END and SELECT-END nesting level. This option enables you to debug mismatched DO-END and SELECT-END statements and is particularly useful in large programs where the nesting level is not obvious.

/ STACK=stack-size: specifies the maximum number of nested LINK statements.

_NULL_: specifies that SAS does not create a data set when it executes the DATA step.

VIEW=view-name: names a view that the DATA step uses to store the input DATA step view.

Restrictions:view-name must match one of the data set names.

SAS creates only one view in a DATA step.

Tips:If you specify additional data sets in the DATA statement, SAS creates these data sets when the view is processed in a subsequent DATA or PROC step. Views have the capability of generating other data sets at the time the view is executed.

SAS macro variables resolve when the view is created. Use the SYMGET function to delay macro variable resolution until the view is processed.

Examples:Creating Input DATA Step Views

Creating a View and a Data File

password-option

assigns a password to a stored compiled DATA step program or a DATA step view.

Note: To DESCRIBE a password-protected DATA step program, you must specify its password. If the program has more than one password, you must specify the most restrictive password. ALTER is the most restrictive, and READ is the least restrictive. For more information, see DESCRIBE Statement.

The following password options are available:

ALTER=alter-password: assigns an ALTER password to a SAS data file. The password enables you to protect or replace a stored compiled DATA step program or a DATA step view.

Alias:PROTECT=

Requirements:If you use an ALTER password in creating a stored compiled DATA step program or a DATA step view, an ALTER password is required to replace the program or view.

If you use an ALTER password in creating a stored compiled DATA step program or a DATA step view, an ALTER password is required to execute a DESCRIBE statement.

READ=read-password: assigns a READ password to a SAS data file. The password enables you to read or execute a stored compiled DATA step program or a DATA step view.

Alias:EXECUTE=

Requirements:If you use a READ password in creating a stored compiled DATA step program or a DATA step view, a READ password is required to execute the program or view.

If you use a READ password in creating a stored compiled DATA step program or a DATA step view, a READ password is required to execute DESCRIBE and EXECUTE statements. If you use an invalid password, SAS will execute the DESCRIBE statement.

Tip:If you use a READ password in creating a stored compiled DATA step program or a DATA step view, no password is required to replace the program or view.

PW=password: assigns a READ and ALTER password, both having the same value.

SOURCE=source-option

specifies one of the following source options:

SAVE: saves the source code that created a stored compiled DATA step program or a DATA step view.

ENCRYPT: encrypts and saves the source code that created a stored compiled DATA step program or a DATA step view.

Tip:If you encrypt source code, use the ALTER password option as well. SAS issues a warning message if you do not use ALTER.

NOSAVE: does not save the source code.

CAUTION:

If you use the NOSAVE option for a DATA step view, the view cannot be migrated or copied from one version of SAS to another version.

Default:SAVE

PGM=program-name: names the stored compiled program that SAS creates or executes in the DATA step. To create a stored compiled program, specify a slash (/) before the PGM= option. To execute a stored compiled program, specify the PGM= option without a slash (/).

Tip:SAS macro variables resolve when the stored program is created. Use the SYMGET function to delay macro variable resolution until the view is processed.

Example:Storing and Executing a Compiled Program

NOLIST: suppresses the output of all variables to the SAS log when the value of _ERROR_ is 1.

Restriction:NOLIST must be the last option in the DATA statement.

Details

Using the DATA Statement

The DATA step begins with the DATA statement. You use the DATA statement to create the following types of output: SAS data sets, data views, and stored programs. You can specify more than one output in a DATA statement. However, only one of the outputs can be a data view. You create a view by specifying the VIEW= option and a stored program by specifying the PGM= option.

Using Both a READ and an ALTER Password

If you use both a READ and an ALTER password in creating a stored compiled DATA step program or a DATA step view, the following items apply:

A READ or ALTER password is required to execute the stored compiled DATA step program or DATA step view.

A READ or ALTER password is required if the stored compiled DATA step program or DATA step view contains both DESCRIBE and EXECUTE statements.

If you use an ALTER password with the DESCRIBE and EXECUTE statements, the following items apply:

SAS executes both the DESCRIBE and the EXECUTE statements.

If you execute a stored compiled DATA step program or DATA step view with an invalid ALTER password:

The DESCRIBE statement does not execute.

In batch mode, the EXECUTE statement has no effect.

In interactive mode, SAS prompts you for a READ password. If the READ password is valid, SAS processes the EXECUTE statement. If it is invalid, SAS does not process the EXECUTE statement.

If you use a READ password with the DESCRIBE and EXECUTE statements, the following items apply:

In interactive mode, SAS prompts you for the ALTER password:

If you enter a valid ALTER password, SAS executes both the DESCRIBE and the EXECUTE statements.

If you enter an invalid ALTER password, SAS processes the EXECUTE statement but not the DESCRIBE statement.

In batch mode, SAS processes the EXECUTE statement but not the DESCRIBE statement.
In both interactive and batch modes, if you specify an invalid READ password SAS does not process the EXECUTE statement.

An ALTER password is required if the stored compiled DATA step program or DATA step view contains a DESCRIBE statement.
An ALTER password is required to replace the stored compiled DATA step program or DATA step view.

Creating an Output Data Set (Form 1)

Use the DATA statement to create one or more output data sets. You can use data set options to customize the output data set. The following DATA step creates two output data sets, EXAMPLE1 and EXAMPLE2. It uses the data set option DROP to prevent the variable IDNUMBER from being written to the EXAMPLE2 data set.

data example1 example2 (drop=IDnumber);
   set sample;
   . . .more SAS statements. . .
run;

When Not Creating a Data Set (Form 2)

Usually, the DATA statement specifies at least one data set name that SAS uses to create an output data set. However, when the purpose of a DATA step is to write a report or to write data to an external file, you might not want to create an output data set. Using the keyword _NULL_ as the data set name causes SAS to execute the DATA step without writing observations to a data set. This example writes to the SAS log the value of Name for each observation. SAS does not create an output data set.

data _NULL_;
   set sample;
   put Name ID;
run;

Creating a DATA Step View (Form 3)

You can create DATA step views and execute them at a later time. The following DATA step example creates a DATA step view. It uses the SOURCE=ENCRYPT option to both save and encrypt the source code.

data phone_list / view=phone_list (source=encrypt);
   set customer_list;
   . . .more SAS statements. . . 
run;

For more information, see DATA Step Views in SAS Language Reference: Concepts.

Creating a Stored Compiled DATA Step Program (Form 4)

The ability to compile and store DATA step programs enables you to execute the stored programs later. Stored compiled DATA step programs can reduce processing costs by eliminating the need to compile DATA step programs repeatedly. The following DATA step example compiles and stores a DATA step program. It uses the ALTER password option, which allows the user to replace an existing stored program, and to protect the stored compiled program from being replaced.

data testfile / pgm=stored.test_program (alter=sales);
   set sales_data;
   . . .more SAS statements. . .
run;

For more information, see Stored Compiled DATA Step Programs in SAS Language Reference: Concepts.

Describing a DATA Step View (Form 5)

The following example uses the DESCRIBE statement in a DATA step view to write a copy of the source code to the SAS log.

data view=inventory;
   describe;
run;

For more information, see the DESCRIBE Statement.

Executing a Stored Compiled DATA Step Program (Form 6)

The following example executes a stored compiled DATA step program. It uses the DESCRIBE statement to write a copy of the source code to the SAS log.

libname stored 'SAS library';
data pgm=stored.employee_list;
   describe;
   execute;
run;

libname stored 'SAS library';
data pgm=stored.test_program;
   describe;
   execute;
   . . .more SAS statements. . . 
run;

For information , see the DESCRIBE Statement and the EXECUTE Statement.

Examples

Example 1: Creating Multiple Data Files and Using Data Set Options

This DATA statement creates more than one data set, and it changes the contents of the output data sets:

data error (keep=subject date weight)
     fitness(label='Exercise Study' 
             rename=(weight=pounds));

The ERROR data set contains three variables. SAS assigns a label to the FITNESS data set and renames the variable weight to pounds.

Example 2: Creating Input DATA Step Views

This DATA step creates an input DATA step view instead of a SAS data file:

libname ourlib 'SAS-library';
data ourlib.test / view=ourlib.test;
   set ourlib.fittest;
   tot=sum(of score1-score10);
run;

Example 3: Creating a View and a Data File

This DATA step creates an input DATA step view named THEIRLIB.TEST and an additional temporary SAS data set named SCORETOT:

libname ourlib 'SAS-library-1';
libname theirlib 'SAS-library-2';
data theirlib.test scoretot
   / view=theirlib.test;
   set ourlib.fittest;
   tot=sum(of score1-score10);
run;

SAS does not create the data file SCORETOT until a subsequent DATA or PROC step processes the view THEIRLIB.TEST.

Example 4: Storing and Executing a Compiled Program

The first DATA step produces a stored compiled program named STORED.SALESFIG:

libname in 'SAS-library-1 ';
libname stored 'SAS-library-2 ';
data salesdata / pgm=stored.salesfig;
   set in.sales;
   qtr1tot=jan+feb+mar;
run;

SAS creates the data set SALESDATA when it executes the stored compiled program STORED.SALESFIG.

data pgm=stored.salesfig;
run;

Example 5: Creating a Custom Report

The second DATA step in this program produces a custom report and uses the _NULL_ keyword to execute the DATA step without creating a SAS data set:

data sales;
   input dept : $10. jan feb mar;
   datalines;
shoes 4344 3555 2666
housewares 3777 4888 7999
appliances 53111 7122 41333
;
data _null_;
   set sales;
   qtr1tot=jan+feb+mar;
   put 'Total Quarterly Sales: ' 
       qtr1tot dollar12.;
run;

Example 6: Using a Password with a Stored Compiled DATA Step Program

The first DATA step creates a stored compiled DATA step program called STORED.ITEMS. This program includes the ALTER password, which limits access to the program.

data sample;
   input Name $ TotalItems $;
   datalines;
Lin 328
Susan 433
Ken 156
Pat 340
;
proc print data=sample;
run;

libname stored 'SAS-library';

data employees / pgm=stored.items (alter=klondike);
   set sample;
   if TotalItems > 200 then output;
   run;

This DATA step executes the stored compiled DATA step program STORED.ITEMS. It uses the DESCRIBE statement to print the source code to the SAS log. Because the program was created with the ALTER password, you must use the password if you use the DESCRIBE statement. If you do not enter the password, SAS will prompt you for it.

data pgm=stored.items (alter=klondike);
   describe;
   execute;
run;

Example 7: Displaying Nesting Levels

The following program has two nesting levels. SAS will generate four log messages, one begin and end message for each nesting level.

data _null_ /nesting;
   do i = 1 to 10;
      do j = 1 to 5;
         put i= j=;
      end;
   end;
run;

Nesting Level Debug (partial SAS log)

6    data _null_ /nesting;
7       do i = 1 to 10;
           -
           719
NOTE 719-185: *** DO begin level 1 ***.
8          do j = 1 to 5;
              -
              719
NOTE 719-185: *** DO begin level 2 ***.
9             put i= j=;
10         end;
           ---
           720
NOTE 720-185: *** DO end level 2 ***.
11      end;
        ---
        720
NOTE 720-185: *** DO end level 1 ***.
12   run;

DATA Statement

Syntax

Form 1:

Form 2:

Form 3:

Form 4:

Form 5:

Form 6:

Without Arguments