A full factorial design in three factors, each at two levels coded as –1 and +1.

proc factex;
   factors Pressure Temperature Time;
   examine design;
run;

A full factorial design in three factors, each at three levels coded as –1, 0, and +1.

proc factex;
   factors Pressure Temperature Time / nlev= 3;
   examine design;
run;

A full factorial design in three factors, each at two levels. The entire design is replicated twice, and the design with recoded factor levels is saved in a SAS data set.

proc factex;
   factors Pressure Temperature Time;
   output out= SavedDesign designrep= 2
          Pressure cvals=('low' 'high')
          Temperature nvals=(200 300)
          Time nvals=(10 20);
run;

A full factorial design in three factors, each at two levels coded as –1 and +1. Each run in the design is replicated three times, and the replicated design is randomized and saved in a SAS data set.

proc factex;
   factors Pressure Temperature Time;
   output out= SavedDesign
          pointrep= 3 randomize;
run;

A full factorial design in three control factors, each at two levels coded as –1 and +1. A noise factor design (outer array) read from a SAS data set is replicated for each run in the control factor design (inner array), and the product design is saved in a SAS data set.

proc factex;
factors+ Pressure Temperature Time;
   output out     =+ SavedDesign
          pointrep=+ OutArray;
run;

A full factorial blocked design in three factors, each at two levels coded as –1 and +1. The design is arranged in two blocks and saved in a SAS data set. By default, the block variable is named BLOCK and the two block levels are numbered 1 and 2.

proc factex;
   factors Pressure Temperature Time;
   blocks nblocks= 2;
   output out= SavedDesign;
run;

A full factorial blocked design in three factors, each at two levels coded as –1 and +1. Each block contains four runs; the block variable is renamed and the block levels of character type are recoded. The design is saved in a SAS data set.

proc factex;
   factors Pressure Temperature Time;
   blocks size= 4;
   output out= SavedDesign
          blockname= Machine cvals=('A' 'B' );
run;

A fractional factorial design of resolution 4 in four factors, each at two levels coded as –1 and +1. The size of the design is eight runs.

proc factex;
   factors Pressure Temperature Time Catalyst;
   size design= 8;
   model resolution= 4;
   examine design;
run;

A one-half fraction of a factorial design in four factors, each at two levels coded as –1 and +1. The design is of maximum resolution. The design points, the alias structure, and the confounding rules are listed.

proc factex;
   factors Pressure Temperature Time Catalyst;
   size fraction= 2;
   model resolution=maximum;
   examine design aliasing confounding;
run;

A one-quarter fraction of a factorial design in six factors, each at two levels coded as –1 and +1. Main effects are estimated, and some two-factor interactions are considered nonnegligible. The design is saved in a SAS data set.

proc factex;
   factors x1-x6;
   size fraction= 4;
   model estimate=( x1 x2 x3 x4 x5 x6 )
         nonneg  =( x1*x5 x1*x6 x5*x6 );
   output out    = SavedDesign;
run;