The FACTEX Procedure

Note: See Resolution IV Augmented Design in the SAS/QC Sample Library.

Box, Hunter, and Hunter (1978) describe an injection molding experiment that involves eight 2-level factors: mold temperature (Temp), moisture content (Moisture), holding pressure (HoldPress), cavity thickness (Thick), booster pressure (BoostPress), cycle time (Time), screw speed (Speed), and gate size (Gate).

The design used has 16 runs and is of resolution 4; it is often denoted as . You can generate this design, shown in Output 7.2.1, with the following statements:

proc factex;
   factors Temp        Moisture HoldPress Thick
           BoostPress  Time     Speed     Gate;
   size design=16;
   model resolution=4;
   examine design aliasing;
run;

The FACTORS statement lists factor names. The option DESIGN=16 of the SIZE statement specifies the design size. The RESOLUTION=4 specifies the resolution of the design. The EXAMINE statement lists points and aliasing.

The alias structure is shown in Output 7.2.2.

Subsequent analysis of the data collected for the design suggests that HoldPress and BoostPress have statistically significant effects. There also seems to be significant effect associated with the sum of the aliased two-factor interactions Temp*BoostPress, Moisture*Time, HoldPress*Speed, and Thick*Gate. This chain of confounded interactions is identified in Output 7.2.2.

A few runs can be added to the design to distinguish between the effects due to these four interactions. You simply need a design in which these four effects are estimable, regardless of all other main effects and interactions. For example, the following statements generate a suitable set of runs:

proc factex nocheck;
   factors Temp        Moisture HoldPress Thick
           BoostPress  Time     Speed     Gate;
   model estimate=(Temp*BoostPress
                   Moisture*Time
                   HoldPress*Speed
                   Thick*Gate);
   size design=min;
   examine design aliasing(2);
run;

The DESIGN=MIN option directs FACTEX to search for the smallest design that allows all four interactions to be estimated. Eight runs are required: see Output 7.2.3.

Output 7.2.4 shows the alias structure of the additional eight runs. Note that the alias chain of interest

Temp*BoostPress=Moisture*Time=HoldPress*Speed=Thick*Gate

from the original design is broken: in this new set of runs, these four interactions are aliased with main effects and with other two-factor interactions, but they are unaliased with each other. Therefore, when these four runs are added to the original 16 runs, the main effects of the eight factors plus the four two-factor interactions that were originally aliased with each other can all be estimated with the 20 runs.