The COUNTREG Procedure

In the study by Long (1997) of the number of published articles by scientists (see the section Getting Started: COUNTREG Procedure), the observed proportion of scientists who publish no articles is 0.3005. The following statements use PROC FREQ to compute the proportion of scientists who publish each observed number of articles. Output 11.2.1 shows the results.

 proc freq data=long97data;
    table art / out=obs;
 run;

PROC COUNTREG is then used to fit Poisson and negative binomial models to the data. For each model, the PROBCOUNT option computes the probability that the number of published articles is , for m = 0 to 10.The following statements compute the estimates for Poisson and negative binomial models. The MEAN procedure is then used to compute the average probability of a zero response.

 proc countreg data=long97data;
    model art=fem mar kid5 phd ment / dist=poisson;
    output out=predpoi probcount(0 to 10);
 run;

 proc means mean data=predpoi;
    var p_0;
 run;

The output from the Poisson model for the COUNTREG and MEAN procedures is shown in Output 11.2.2.

The following statements show the syntax for the negative binomial model:

 proc countreg data=long97data;
    model art=fem mar kid5 phd ment / dist=negbin(p=2) method=qn;
    output out=prednb probcount(0 to 10);
 run;

 proc means mean data=prednb;
    var p_0;
 run;

Output 11.2.3 shows the results of the preceding statements.

For each model, the predicted proportion of zero articles can be calculated as the average predicted probability of zero articles across all scientists. Under the Poisson model, the predicted proportion of zero articles is 0.2092, which considerably underestimates the observed proportion. The negative binomial more closely estimates the proportion of zeros (0.3036). Also, the test of the dispersion parameter, _Alpha, in the negative binomial model indicates significant overdispersion (). As a result, the negative binomial model is preferred to the Poisson model.

Another way to account for the large number of zeros in this data set is to fit a zero-inflated Poisson (ZIP) or a zero-inflated negative binomial (ZINB) model. In the following statements, DIST=ZIP requests the ZIP model. In the ZEROMODEL statement, you can specify the predictors, , for the process that generated the additional zeros. The ZEROMODEL statement also specifies the model for the probability . By default, a logistic model is used for . The default can be changed using the LINK= option. In this particular ZIP model, all variables used to model the article counts are also used to model .

 proc countreg data=long97data;
    model art = fem mar kid5 phd ment / dist=zip;
    zeromodel art ~ fem mar kid5 phd ment;
    output out=predzip probcount(0 to 10);
 run;

 proc means data=predzip mean;
    var p_0;
 run;

The parameters of the ZIP model are displayed in Output 11.2.4. The first set of parameters gives the estimates of in the model for the Poisson process mean. Parameters with the prefix “Inf_” are the estimates of in the logistic model for .

The proportion of zeros predicted by the ZIP model is 0.2986, which is much closer to the observed proportion than the Poisson model. But Output 11.2.6 shows that both models deviate from the observed proportions at one, two, and three articles.

The ZINB model is specified by the DIST=ZINB option. All variables are again used to model both the number of articles and . The METHOD=QN option specifies that the quasi-Newton method be used to fit the model rather than the default Newton-Raphson method. These options are implemented in the following statements:

 proc countreg data=long97data;
    model art=fem mar kid5 phd ment / dist=zinb method=qn;
    zeromodel art ~ fem mar kid5 phd ment;
    output out=predzinb probcount(0 to 10);
 run;

 proc means data=predzinb mean;
    var p_0;
 run;

The estimated parameters of the ZINB model are shown in Output 11.2.5. The test for overdispersion again indicates a preference for the negative binomial version of the zero-inflated model (). The ZINB model also does a good job of estimating the proportion of zeros (0.3119), and it follows the observed proportions well, though possibly not as well as the negative binomial model.

The following statements compute the average predicted count probability across all scientists for each count 0, 1, , 10. The averages for each model, along with the observed proportions, are then arranged for plotting by PROC SGPLOT.

 proc summary data=predpoi;
     var p_0-p_10;
     output out=mnpoi mean(p_0-p_10)=mn0-mn10;
 run;
 proc summary data=prednb;
     var p_0-p_10;
     output out=mnnb mean(p_0-p_10)=mn0-mn10;
 run;
 proc summary data=predzip;
     var p_0-p_10;
     output out=mnzip mean(p_0-p_10)=mn0-mn10;
 run;
 proc summary data=predzinb;
     var p_0-p_10;
     output out=mnzinb mean(p_0-p_10)=mn0-mn10;
 run;


 data means;
    set mnpoi mnnb mnzip mnzinb;
    drop _type_ _freq_;
 run;

 proc transpose data=means out=tmeans;
 run;

 data allpred;
    merge obs(where=(art<=10)) tmeans;
    obs=percent/100;
 run;

 proc sgplot;
    yaxis label='Probability';
    xaxis label='Number of Articles';
    series y=obs  x=art / name='obs' legendlabel='Observed'
       lineattrs=(color=black thickness=4px);
    series y=col1 x=art / name='poi' legendlabel='Poisson'
       lineattrs=(color=blue);
    series y=col2 x=art/ name='nb' legendlabel='Negative Binomial'
       lineattrs=(color=red);
    series y=col3 x=art/ name='zip' legendlabel='ZIP'
       lineattrs=(color=blue pattern=2);
    series y=col4 x=art/ name='zinb' legendlabel='ZINB'
       lineattrs=(color=red pattern=2);
    discretelegend 'poi' 'zip' 'nb' 'zinb' 'obs' / title='Models:'
       location=inside position=ne across=2 down=3;
 run;

For each of the four fitted models, Output 11.2.6 shows the average predicted count probability for each article count across all scientists. The Poisson model clearly underestimates the proportion of zero articles published, while the other three models are quite accurate at zero. All of the models do well at the larger numbers of articles.