The SASECRSP Interface Engine

The INSET= option enables you to select any companies and/or issues you want data for. This example selects two CRSP Index Series from the Indices database, two companies from the CCM database, and four securities from the Stock database for data extraction. Note that because each CRSP database might be in a different location and has to be opened separately, a total of three different librefs are used, one for each database.

data indices;
   indno=1000000; output;  /* NYSE Value-Weighted Market Index */
   indno=1000001; output;  /* NYSE Equal-Weighted Market Index */
run;

libname _all_ clear;
libname ind2 sasecrsp "%sysget(CRSP_MSTK)"
        setid=420
        inset='indices,INDNO,INDNO'
        range='19990101-19990401';

title2 'Total Returns for NYSE Value and Equal Weighted Market Indices';
proc print data=ind2.tret label;
run;

Output 39.4.1 shows the result of selecting two CRSP Index Series from the Indices database.

This example selects two companies from the CCM database.

data companies;
   permco=8045;  output;  /* Oracle */
   permco=20483; output;  /* Citigroup */
run;

libname comp2 sasecrsp "%sysget(CRSP_CST)"
        setid=200
        inset='companies,PERMCO,PERMCO'
        range='20040101-20040531';

title2 'Using the Link Info of Selected PERMCOs';
proc print data=comp2.link label;
run;

title3 'To Show Dividends Per Share for Oracle and Citigroup';
proc print data=comp2.div label;
run;

Output 39.4.2 shows the result of selecting two companies from the CCM database by using the CCM LINK data and the INSET= option.

Output 39.4.3 shows the result of selecting two companies from the CCM database by using the CCM DIV data and the INSET= option.

This example selects three securities from the Stock database by using TICKERs in the INSET= option for data extraction.

data securities;
   ticker='BAC'; output;  /* Bank of America */
   ticker='DUK'; output;  /* Duke Energy */
   ticker='GSK'; output;  /* GlaxoSmithKline */
run;

libname sec3 sasecrsp "%sysget(CRSP_MSTK)"
        setid=20
        inset='securities,TICKER,TICKER'
        range='19970820-19970920';

title2 'PERMNOs and General Header Info of Selected TICKERs';
proc print data=sec3.stkhead(keep=permno htick htsymbol) label;
run;
title3 'Average Price for Bank of America, Duke and GlaxoSmithKline';
proc print data=sec3.prc label;
run;

Output 39.4.4 shows the STK header data for the TICKERs specified by using the INSET= option.

Output 39.4.5 shows the STK price data for the TICKERs specified by using the INSET= option.