Example 7.11 Resolution 4 Design with Minimum Aberration

See FACTEX14 in the SAS/QC Sample LibraryIf a design has resolution 4, then you can simultaneously estimate all main effects and some two-factor interactions. However, not all resolution 4 designs are equivalent; you might be able to estimate more two-factor interactions with some than with others. Among all resolution 4 designs, a design with the maximum number of estimable two-factor interactions is said to have minimum aberration.

For example, if you use the FACTEX procedure to generate a resolution 4 2-level design in 32 runs for seven factors, you can estimate all main effects and 15 of the 21 two-factor interactions with the design that is created by default. The following statements create this design and display its alias structure in Output 7.11.1:

proc factex;
   factors A B C D E F G;       
   model resolution=4;          
   size design=32;                 
   examine aliasing;          
run;

Output 7.11.1: Alias Structure for Default $2^{7-2}_\mr {IV}$ Design

The FACTEX Procedure

Aliasing Structure
A
B
C
D
E
F
G
AB = FG
A*C
A*D
A*E
AF = BG
AG = BF
B*C
B*D
B*E
CD = EG
CE = DG
C*F
CG = DE
D*F
E*F

In contrast, the resolution 4 design given in Table 12.15 of Box, Hunter, and Hunter (1978) is a minimum aberration design that permits estimation of 18 two-factor interactions, three more than can be estimated with the default design. The FACTEX procedure constructs the minimum aberration design if you specify the MINABS option in the MODEL statement, as in the following statements:

proc factex;
   factors A B C D E F G;      
   model resolution=4 / minabs;
   size design=32;          
   examine aliasing;              
run;

The alias structure for the resulting design is shown in Output 7.11.2.

Output 7.11.2: Alias Structure for Minimum Aberration $2^{7-2}_\mr {IV}$ Design

The FACTEX Procedure

Aliasing Structure
A
B
C
D
E
F
G
A*B
A*C
A*D
A*E
A*F
A*G
B*C
B*D
B*E
B*F
B*G
CD = EF
CE = DF
CF = DE
C*G
D*G
E*G
F*G

All of the designs listed in Table 12.15 of Box, Hunter, and Hunter (1978) have minimum aberration. For most of these cases, the default design constructed by the FACTEX procedure has minimum aberration—that is, the MINABS option is not required. This is important because the MINABS option forces the FACTEX procedure to check many more designs, and the search can therefore take longer to run. You can limit the search time with the TIME= option in the PROC FACTEX statement. In five of the cases ( $2^{10-6}_\mr {III}$ , $2^{7-2}_\mr {IV}$ , $2^{8-3}_\mr {IV}$ , $2^{9-4}_\mr {IV}$ , and $2^{10-3}_\mr {V}$ ), the MINABS option is required to construct a design with minimum aberration, and in two cases ( $2^{9-5}_\mr {III}$ , $2^{9-3}_\mr {IV}$ ), the NOCHECK option is also required. If the FACTEX procedure is given sufficient time to run, specifying both the MINABS and the NOCHECK options always results in a minimum aberration design. However, with the default search time of 60 seconds, there are three cases ( $2^{10-5}_\mr {IV}$ , $2^{10-4}_\mr {IV}$ , and $2^{11-5}_\mr {IV}$ ) for which the FACTEX procedure is unable to find the minimum aberration design, even with both the MINABS and NOCHECK options specified.