See FACTEX18 in the SAS/QC Sample LibraryIn split-plot designs, not all factor levels can change from plot to plot. In the simplest split-plot structure, runs are grouped into whole plots; certain factors are applied to all plots in the whole plot, while others are applied to individual plots within a whole plot. The two types of factors are termed whole-plot factors and subplot factors, respectively. Split-plot designs are very common in chemical and process industries, where factors of interest are often applied at different stages of the production process and the final measurements of interest are made on the finished product. In this case, the different stages of production might give rise to multiple whole-plot effects.

Suppose you are designing an experiment to measure six factors that affect characteristics of metal wires sheathed with a certain material. Three of the factors (W1, W2, W3) apply to how the wires themselves are made, and the other three (S1, S2, S3) apply to the sheathing material. You propose to first prepare eight different batches of wire, making two wires from each batch, and then to prepare the sheathing material for each wire individually. This describes a standard split-plot experiment with batches of wires forming whole plots and sheathed wires forming subplots. The following code constructs a resolution 4 design for this experiment, specifying the Wire unit effect in the BLOCKS statement, and then in the UNITEFFECT statement specifying that W1, W2, and W3 should be constant within Wire and that S1, S2, and S3 should change within Wire. The resulting design is printed, sorted by Wire.

proc factex;
   factors W1 W2 W3 
           S1 S2 S3;          
   size design=16;
   blocks units=(Wire=8);
   model r=4;
   uniteffect Wire / whole=(W1 W2 W3) 
                     sub  =(S1 S2 S3);
   examine aliasing(units);                        
   output out=WireExperiment1;
run;

proc sort data=WireExperiment1;
   by Wire W1-W3 S1-S3;
run;
proc print data=WireExperiment1;
run;

Output 7.15.1 shows the aliasing structure for the design, which indicates that the main effects of the wire factors are indeed estimated on the Wire whole plots and the main effects of the sheath factors are estimated on the subplots. Interestingly, some of the sheath factor interactions are also confounded with whole plots.

The final design is listed in Output 7.15.2. Notice that the factors W1, W2, and W3 are constant within Wire, while S1, S2, and S3 change within Wire.

To see why the Wire factors are constant within wire and the sheath factors change, examine the confounding rules for the design. The following statements produce the table of confounding rules listed in Output 7.15.3:

proc factex;
   factors W1 W2 W3
           S1 S2 S3;
   size design=16;
   blocks units=(Wire=8);
   model r=4;
   uniteffect Wire / whole=(W1 W2 W3) 
                     sub  =(S1 S2 S3);
   examine confounding;
run;

The terms [i] on the right-hand side of these rules denote plot-indexing pseudo-factors, as discussed in the section Split-Plot Designs. Note that the wire factors W1, W2, and W3 are confounded only with interactions between the first three pseudo-factors, the ones identified with the eight levels of the Wire unitfactor. This guarantees that these factors are constant within levels of Wire. By contrast, the confounding rules for the sheath factors S1, S2, and S3 each involve the fourth pseudo-factor, so they must change within levels of Wire.

There are only eight different combinations of the sheath factors, but the previous design requires you to produce batches of sheath material 16 times, once for each of the two wires to be made from each wire batch. If instead you propose to make just four batches of sheath material and apply part of each batch to parts of different batches of wires, the design becomes a row-column design instead of a split-plot design. Furthermore, suppose that the number of batches rather than the size of each batch is the main cost, so that you can prepare eight batches of wire and four batches of sheathing material in sufficient quantity to make 64 different sheathed wires. Since there can be only four different combinations of the three sheathing factors, each sheathing factor interaction is aliased with a main effect, and thus the design necessarily has resolution 3. All other interactions are estimable free of main effects. The following FACTEX statements create the design and display the two unit effects with their respective wholeunit factor levels:

proc factex;
   factors W1 W2 W3 
           S1 S2 S3;
   size design=64;
   blocks units=(Wire=8 Sheath=4);
   model r=3;
   uniteffect Wire   / whole=(W1 W2 W3);
   uniteffect Sheath / whole=(S1 S2 S3);
   examine aliasing(units);                        
   output out=WireExperiment2;
proc freq data=WireExperiment2;
   table Wire  *W1*W2*W3 / list nocum nopct;
   table Sheath*S1*S2*S3 / list nocum nopct;
run;

The results, listed in Output 7.15.4 and Output 7.15.5, indicate that W1, W2, and W3 are constant within Wire and S1, S2, and S3 are constant within Sheath.