UCHART Statement: ANOM Procedure

Saving Decision Limits

Note: See Saving Decision Limits Using ANOM UCHART in the SAS/QC Sample Library.

You can save the decision limits for an ANOM u chart in a SAS data set.

The following statements read the data set MSAdmits (see Creating ANOM Charts for Rates from Group Counts) and save the decision limits displayed in Figure 4.18 in a data set named MSLimits:

proc anom data=MSAdmits;
   uchart Count*ID / groupn    = KMemberYrs
                     outlimits = MSLimits
                     nochart;
run;

The GROUPN= option specifies the number of opportunity units for each group. The OUTLIMITS= option names the data set containing the decision limits, and the NOCHART option suppresses the display of the chart. The data set MSLimits is listed in Figure 4.19.

Figure 4.19: Data Set MSLimits Containing Decision Limits

Decision Limits for Medical/Surgical Admissions Rates

_VAR_	_GROUP_	_TYPE_	_LIMITN_	_ALPHA_	_LDLU_	_U_	_UDLU_	_LIMITK_
Count	ID	ESTIMATE	V	0.05	V	33.0789	V	29

The data set MSLimits contains one observation with the limits for response Count. The variables _LDLU_ and _UDLU_ contain the lower and upper decision limits, and the variable _U_ contains the central line. The value of _LIMITN_ is the nominal number of units associated with the decision limits (which are varying in this case), the value of _LIMITK_ is the number of groups, and the value of _ALPHA_ is the significance level of the decision limits. The variables _VAR_ and _GROUP_ are bookkeeping variables that save the response and group-variable. The variable _TYPE_ is a bookkeeping variable that indicates whether the value of _U_ is an estimate or standard (known) value. Typically, the value of _TYPE_ is 'ESTIMATE.' For more information, see OUTLIMITS= Data Set.

Alternatively, you can use the OUTTABLE= option to create an output data set that saves both the decision limits and the group statistics, as illustrated by the following statements:

proc anom data=MSAdmits;
   uchart Count*ID / groupn   = KMemberYrs
                     outtable = MSTable
                     nochart;
run;

The a partial listing of the data set MSTable is shown in Figure 4.20.

Figure 4.20: Data Set MSTable

Rates and Decision Limits for Medical/Surgical Admissions

_VAR_	ID	_ALPHA_	_LIMITN_	_SUBN_	_LDLU_	_SUBU_	_U_	_UDLU_	_EXLIM_
Count	1A	0.05	58.1003	58.1003	31.2135	32.3922	33.0789	34.9443
Count	1B	0.05	12.8933	12.8933	28.2837	33.9710	33.0789	37.8741
Count	1C	0.05	2.6633	2.6633	22.1550	37.5481	33.0789	44.0028
Count	1D	0.05	6.8545	6.8545	26.3640	46.3929	33.0789	39.7938	UPPER
Count	1E	0.05	4.2691	4.2691	24.4964	40.0554	33.0789	41.6615
Count	1F	0.05	0.2020	0.2020	0.0000	34.6535	33.0789	73.0631
Count	1G	0.05	0.8626	0.8626	13.7710	32.4606	33.0789	52.3868
Count	1H	0.05	2.3985	2.3985	21.5579	46.6959	33.0789	44.5999	UPPER
Count	1I	0.05	0.5034	0.5034	7.7757	49.6607	33.0789	58.3822
Count	1J	0.05	1.5918	1.5918	18.8992	33.9249	33.0789	47.2587

This data set contains one observation for each group. The variables _SUBU_ and _SUBN_ contain the rate of occurrence and the number of opportunity units for each group. The variables _LDLU_ and _UDLU_ contain the lower and upper decision limits, and the variable _U_ contains the central line. The variables _VAR_ and ID contain the response name and values of the group-variable, respectively. For more information, see OUTTABLE= Data Set.

Note: See Saving ANOM UCHART Summary Statistics and Decision Limits in the SAS/QC Sample Library.

An OUTTABLE= data set can be read later as a TABLE= data set by the ANOM procedure. For example, the following statements read MSTable and display a u chart (not shown here) identical to the chart in Figure 4.18:

title 'Analysis of Medical/Surgical Admissions';
proc anom table=MSTable;
   uchart Count*id ;
   label _subu_ = 'Admits per 1000 Member Years';
run;

Because the ANOM procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized ANOM charts. For more information, see the section TABLE= Data Set.