Note: See A Design for a Three-Step Process in the SAS/QC Sample Library.
Ramirez and Weisz (2009) discuss an experiment on a multistep milling process with 16 processing factors, with a single factor applied at the first stage, seven more factors at the second stage, and eight more at the final stage. The experiment involves eight first-stage runs, eight second-stage runs within each of those, and again, two to four third-stage runs within each of those, for a total of 128 to 256 total experimental units. This example explores several different ways to design this experiment, depending on what kinds of effects are most important.
The following statements request a design of maximum resolution for this split-plot structure. The factors are listed in macro variables, for ease in specifying them in UNITEFFECT statements. The BLOCK statement defines the unit factors for the first two processing stages, with eight runs of each. The two UNITEFFECT statements then use these unit factors to specify which unit effects correspond to which factors. Finally, the EXAMINE statement requests that the aliasing structure and the overall modeling summary be displayed to see how many effects of different orders are estimable and clear. The UNITS suboption of the ALIASING option includes the unit effect confounding for each alias string in the alias structure.
%let F1 = Z; %let F2 = A B C D E F G; %let F3 = P Q R S T U V W; proc factex; factors &F1 &F2 &F3; model r=max; size design=128; blocks units=(Step1=8 Step2=8); uniteffect Step1 / whole=(&F1) sub=(&F2 &F3); uniteffect Step1*Step2 / whole=(&F2) sub=( &F3); examine aliasing(units) summary; quit;
Output 7.16.1: Aliasing for Default 128-Run Three-Step Design
| Aliasing Structure | |
|---|---|
| Units | |
| Step1 | Z |
| Step1 | A*B = C*D = E*F = P*Q = R*S = T*U = V*W |
| Step1 | A*C = B*D = E*G = P*R = Q*S = T*V = U*W |
| Step1 | A*D = B*C = F*G = P*S = Q*R = T*W = U*V |
| Step1*Step2 | A |
| Step1*Step2 | B |
| Step1*Step2 | C |
| Step1*Step2 | D |
| Step1*Step2 | E |
| Step1*Step2 | F |
| Step1*Step2 | G |
| Step1*Step2 | Z*A |
| Step1*Step2 | Z*B |
| Step1*Step2 | Z*C |
| Step1*Step2 | Z*D |
| Step1*Step2 | Z*E |
| Step1*Step2 | Z*F |
| Step1*Step2 | Z*G |
| Step1*Step2 | A*E = B*F = C*G = P*T = Q*U = R*V = S*W |
| Step1*Step2 | A*F = B*E = D*G = P*U = Q*T = R*W = S*V |
| Step1*Step2 | A*G = C*E = D*F = P*V = Q*W = R*T = S*U |
| Step1*Step2 | B*G = C*F = D*E = P*W = Q*V = R*U = S*T |
| Residual | P |
| Residual | Q |
| Residual | R |
| Residual | S |
| Residual | T |
| Residual | U |
| Residual | V |
| Residual | W |
| Residual | Z*P |
| Residual | Z*Q |
| Residual | Z*R |
| Residual | Z*S |
| Residual | Z*T |
| Residual | Z*U |
| Residual | Z*V |
| Residual | Z*W |
| Residual | A*P = B*Q = C*R = D*S = E*T = F*U = G*V |
| Residual | A*Q = B*P = C*S = D*R = E*U = F*T = G*W |
| Residual | A*R = B*S = C*P = D*Q = E*V = F*W = G*T |
| Residual | A*S = B*R = C*Q = D*P = E*W = F*V = G*U |
| Residual | A*T = B*U = C*V = D*W = E*P = F*Q = G*R |
| Residual | A*U = B*T = C*W = D*V = E*Q = F*P = G*S |
| Residual | A*V = B*W = C*T = D*U = E*R = F*S = G*P |
| Residual | A*W = B*V = C*U = D*T = E*S = F*R = G*Q |
Output 7.16.2: Modeling Summary for Default 128-Run Three-Step Design
| Modeling Summary | ||
|---|---|---|
| Effects | ||
| Main | 2FI | |
| Total | 16 | 120 |
| Estimable | 16 | 30 |
| Clear | 16 | 15 |
The resulting design has resolution 4, which means that main effects are clear of two-factor interactions but interactions
are aliased with each other. Output 7.16.1 shows which interactions are aliased and also shows which units are used to estimate them. Note that several interactions
between Step2 and Step3 factors are estimated with Step2 units.
As Output 7.16.2 shows, only 30/120=25% of the two-factor interactions (2FI) are estimable and only 15/120=13% of them are clear. If simply protecting the main-effects estimates against potential two-factor interactions is sufficient, then this design suffices. However, if you want to estimate as many of the two-factor interactions as possible, then you should look for a MaxClear design. The following statements use the MAXCLEAR option in the MODEL statement to request a MaxClear design, and they also use the ORDER=RANDOM(RESTART) option in the PROC FACTEX statement to improve the chances that the best design is found. For more details about MaxClear designs, see the section MaxClear Designs.
%let F1 = Z; %let F2 = A B C D E F G; %let F3 = P Q R S T U V W; proc factex order=random(restart seed=1); factors &F1 &F2 &F3; model r=max / maxclear; size design=128; blocks units=(Step1=8 Step2=8); uniteffect Step1 / whole=(&F1) sub=(&F2 &F3); uniteffect Step1*Step2 / whole=(&F2) sub=( &F3); examine summary; quit;
Output 7.16.3: Modeling Summary for MaxClear 128-Run Three-Step Design
| Modeling Summary | ||
|---|---|---|
| Effects | ||
| Main | 2FI | |
| Total | 16 | 120 |
| Estimable | 16 | 87 |
| Clear | 16 | 69 |
The modeling summary results for the MaxClear design are shown in Output 7.16.3. Now 87/120=73% of the 2FI are estimable and 69/120=58% of them clear. This is a great improvement over the default design, but if complete estimability of all two-factor interactions is required, more than 128 runs are necessary. The following statements construct a design in 256 runs, effectively doubling the number of third-stage runs from two to four:
%let F1 = Z; %let F2 = A B C D E F G; %let F3 = P Q R S T U V W; proc factex; factors &F1 &F2 &F3; model r=max; size design=256; blocks units=(Step1=8 Step2=8); uniteffect Step1 / whole=(&F1) sub=(&F2 &F3); uniteffect Step1*Step2 / whole=(&F2) sub=( &F3); examine aliasing(units); quit;
The aliasing structure (not shown) shows that the resulting design has resolution 5, which means that all main effects and two factor interactions are estimable free of each other. Even though the required 256 runs means this is a relatively large experiment, it is still only a tiny fraction of the 65,536 runs required for a complete factorial design.