Note: See A Strip-Split-Split-Plot Design in the SAS/QC Sample Library.

Suppose you are designing an experiment for a three-step process running on different machines. One way to model this is with a rowcolumn strip-split-split-plot structure, with one type of unit, Machine, crossed with a process that has a split-split-plot structure. The following statements create a resolution 4 design in 11 factors for this situation, with one Machine factor MSetting and three, three, and five whole plot, split-plot, and split-split-plot process factors, respectively. The statements also specify that the design’s aliasing structure and modeling summary be displayed, with the unit effect confounding for each alias string included in the alias structure.

%let FR = X11-X13;
%let FC = X21-X23;
%let FX = X31-X35;
proc factex;
   factors MSetting &FR &FC &FX;
   model r=4;
   blocks units=(Machine=2 Step1=8 Step2=4 Step3=2);
   uniteffect Machine           / whole=(MSetting);
   uniteffect Step1             / whole=(&FR) sub=(&FC &FX);
   uniteffect Step1*Step2       / whole=(&FC) sub=(    &FX);
   uniteffect Step1*Step2*Step3 / whole=(&FX);
   size design=128;
   examine aliasing(units) summary;
run;

The UNITEFFECT statements define a triply nested split-plot structure for the process on each machine, including the Step1*Step2*Step3 split-split units for the process, in order to ensure that process effects are crossed with Machine.

As Output 7.17.1 shows, 36/66=55% of the 2FI are estimable and 21/66=32% of them are clear. The aliasing structure (not shown) indicates that the main effect of MSetting is the only thing that is estimated with the Machine units; all interactions between MSetting and the process factors are estimated with the experimental units, labeled “Residual” in the alias structure.

If simply protecting the main-effects estimates against potential two-factor interactions is the reason for requiring a resolution 4 design, then the design of Output 7.17.1 suffices. However, if you want to estimate as many of the two-factor interactions as possible, then you should use the MAXCLEAR option in the MODEL statement to construct a MaxClear design, as shown in the following statements:

%let FR = X11-X13;
%let FC = X21-X23;
%let FX = X31-X35;
proc factex order=random(restart seed=230501);
   factors MSetting &FR &FC &FX;
   model r=4 / maxclear;
   blocks units=(Machine=2 Step1=8 Step2=4 Step3=2);
   uniteffect Machine           / whole=(MSetting);
   uniteffect Step1             / whole=(&FR) sub=(&FC &FX);
   uniteffect Step1*Step2       / whole=(&FC) sub=(    &FX);
   uniteffect Step1*Step2*Step3 / whole=(&FX);
   size design=128;
   examine summary;
run;

As Output 7.17.2 shows, now 55/66=83% of the 2FI are estimable and 45/66=68% of them are clear—more than twice as many clear interactions as before.

For details about MaxClear designs, see the section MaxClear Designs.