BOXCHART Statement: SHEWHART Procedure

Note: See Box Chart Examples in the SAS/QC Sample Library.

You can save the control limits for a box chart in a SAS data set; this enables you to apply the control limits to future data (see Reading Preestablished Control Limits) or modify the limits with a DATA step program.

The following statements read measurements from the data set Turbine (see Creating Box Charts from Raw Data) and save the control limits displayed in Figure 17.4 in a data set named TURBLIM:

proc shewhart data=Turbine;
   boxchart KWatts*Day / outlimits=Turblim
                         nochart;
run;

The OUTLIMITS= option names the data set containing the control limits, and the NOCHART option suppresses the display of the chart. The data set Turblim is listed in Figure 17.10.

The data set Turblim contains one observation with the limits for process KWatts. The variables _LCLX_ and _UCLX_ contain the lower and upper control limits for the means, and the variable _MEAN_ contains the central line. The value of _MEAN_ is an estimate of the process mean, and the value of _STDDEV_ is an estimate of the process standard deviation . The value of _LIMITN_ is the nominal sample size associated with the control limits, and the value of _SIGMAS_ is the multiple of associated with the control limits. The variables _VAR_ and _SUBGRP_ are bookkeeping variables that save the process and subgroup-variable. The variable _TYPE_ is a bookkeeping variable that indicates whether the values of _MEAN_ and _STDDEV_ are estimates or standard values.

The variables _LCLS_, _S_, and _UCLS_ are not used to create box charts, but they are included so that the data set Turblim can be used to create an s chart; see XSCHART Statement: SHEWHART Procedure. If you specify the RANGES option in the BOXCHART statement, the variables _LCLR_, _R_, and _UCLR_, rather than the variables _LCLS_, _S_, and _UCLS_, are included in the OUTLIMITS= data set. These variables can be used to create an R chart; see XRCHART Statement: SHEWHART Procedure.

If you specify CONTROLSTAT=MEDIAN to request control limits for medians, the variables _LCLM_ and _UCLM_, rather than the variables _LCLX_ and _UCLX_, are included in the OUTLIMITS= data set as demonstrated by the following statements:

proc shewhart data=Turbine;
   boxchart KWatts*Day / outlimits   = Turblim2
                         controlstat = median
                         nochart;
run;

Turblim2 is listed in Figure 17.11. For more information, see OUTLIMITS= Data Set.

You can create an output data set containing both control limits and summary statistics with the OUTTABLE= option, as illustrated by the following statements:

title 'Summary Statistics and Control Limit Information';
proc shewhart data=Turbine;
   boxchart KWatts*Day / outtable=Turbtab
                         nochart;
run;

The data set Turbtab is partially listed in Figure 17.12.

This data set contains one observation for each subgroup sample. The variable _SUBMIN_ contains the subgroup minimums, and the variable _SUBQ1_ contains the first quartile for each subgroup. The variable _SUBX_ contains the subgroup means, and the variable _SUBMED_ contains the subgroup medians. The variable _SUBQ3_ contains the third quartiles, and the variable _SUBMAX_ contains the subgroup maximums. The variable _SUBN_ contains the subgroup sample sizes. The variables _LCLX_ and _UCLX_ contain the lower and upper control limits for the means. The variable _MEAN_ contains the central line. The variables _VAR_ and Day contain the process name and values of the subgroup-variable, respectively. For more information, see OUTTABLE= Data Set.

An OUTTABLE= data set can be read later as a TABLE= data set. For example, the following statements read Turbtab and display a box chart (not shown here) identical to the chart in Figure 17.4:

title 'Box Chart for Power Output';
proc shewhart table=Turbtab;
   boxchart KWatts*Day;
label _SUBX_ = 'Average Power Output';
run;

Because the SHEWHART procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized control charts (see Specialized Control Charts: SHEWHART Procedure).

For more information, see TABLE= Data Set.