HISTOGRAM Statement: CAPABILITY Procedure

Note: See Nonnormal Distribution Capability Indices in the SAS/QC Sample Library.

Standard capability indices such as are generally considered meaningful only if the process output has a normal (or reasonably normal) distribution. In practice, however, many processes have nonnormal distributions. This example, which is a continuation of Example 5.9 and Example 5.10, shows how you can use the HISTOGRAM statement to compute generalized capability indices based on fitted nonnormal distributions.

The following statements produce printed output that is partially listed in Output 5.11.1 and Output 5.11.2:

data Plates;
   label Gap='Plate Gap in cm';
   input Gap @@;
   datalines;
0.746  0.357  0.376  0.327  0.485 1.741  0.241  0.777  0.768  0.409
0.252  0.512  0.534  1.656  0.742 0.378  0.714  1.121  0.597  0.231
0.541  0.805  0.682  0.418  0.506 0.501  0.247  0.922  0.880  0.344
0.519  1.302  0.275  0.601  0.388 0.450  0.845  0.319  0.486  0.529
1.547  0.690  0.676  0.314  0.736 0.643  0.483  0.352  0.636  1.080
;

proc capability data=Plates checkindices(alpha=0.05);
   specs lsl=0.3 usl= 0.8;
   histogram Gap / lognormal(indices) noplot;
run;

The PROC CAPABILITY statement computes the standard capability indices that are shown in Output 5.11.1.

The CHECKINDICES option in the PROC statement requests a goodness-of-fit test for normality in conjunction with the indices and displays the warning that normality is rejected at the significance level .

Example 5.9 concluded that the fitted lognormal distribution summarized in Output 5.9.2 is a good model, so one might consider computing generalized capability indices based on this distribution. These indices are requested with the INDICES option and are shown in Output 5.11.2. Formulas and recommendations for these indices are given in Indices Using Fitted Curves.