The HPMIXED Procedure

The following data are from Pothoff and Roy (1964) and consist of growth measurements for 11 girls and 16 boys at ages 8, 10, 12, and 14. Some of the observations are suspect (for example, the third observation for person 20); however, all of the data are used here for comparison purposes.

The analysis strategy employs a linear growth curve model for the boys and girls in addition to a variance-covariance model that incorporates correlations for all of the observations that arise from the same person. The PROC HPMIXED statements to fit an unstructured variance matrix are as follows:

data pr;
   input Person Gender $ y1 y2 y3 y4;
   y=y1; Time=1; Age=8;  output;
   y=y2; Time=2; Age=10; output;
   y=y3; Time=3; Age=12; output;
   y=y4; Time=4; Age=14; output;
   drop y1-y4;
   datalines;
 1   F   21.0    20.0    21.5    23.0
 2   F   21.0    21.5    24.0    25.5
 3   F   20.5    24.0    24.5    26.0
 4   F   23.5    24.5    25.0    26.5
 5   F   21.5    23.0    22.5    23.5
 6   F   20.0    21.0    21.0    22.5
 7   F   21.5    22.5    23.0    25.0
 8   F   23.0    23.0    23.5    24.0
 9   F   20.0    21.0    22.0    21.5
10   F   16.5    19.0    19.0    19.5
11   F   24.5    25.0    28.0    28.0
12   M   26.0    25.0    29.0    31.0
13   M   21.5    22.5    23.0    26.5
14   M   23.0    22.5    24.0    27.5
15   M   25.5    27.5    26.5    27.0
16   M   20.0    23.5    22.5    26.0
17   M   24.5    25.5    27.0    28.5
18   M   22.0    22.0    24.5    26.5
19   M   24.0    21.5    24.5    25.5
20   M   23.0    20.5    31.0    26.0
21   M   27.5    28.0    31.0    31.5
22   M   23.0    23.0    23.5    25.0
23   M   21.5    23.5    24.0    28.0
24   M   17.0    24.5    26.0    29.5
25   M   22.5    25.5    25.5    26.0
26   M   23.0    24.5    26.0    30.0
27   M   22.0    21.5    23.5    25.0
;

proc hpmixed data=pr;
   class Person Gender Time;
   model y = Gender Age Gender*Age;
   test Gender Age Gender*Age;
   repeated Time / type=un subject=Person r;
run;

The MODEL statement first lists the dependent variable Y. The fixed effects are then listed after the equal sign. The variable Gender requests a different intercept for the girls and boys, Age models an overall linear growth trend, and Gender*Age makes the slopes different over time. It is actually not necessary to specify Age separately, but doing so enables PROC HPMIXED to carry out a test for heterogeneous slopes.

The REPEATED statement contains a repeated-effect Time. The TYPE=UN option models the covariance as an unstructured block for each SUBJECT=Person. Each of the 27 subjects has a maximum of four observations. Therefore, the matrix is block diagonal with 27 blocks, each block consisting of identical 44 unstructured matrices. The 10 parameters of these unstructured blocks make up the covariance parameters estimated by restricted maximum likelihood. The R= option requests that the first block of be displayed.

The results from this analysis are shown in Output 48.5.1 through Output 48.5.5.

In Output 48.5.1, the 10 covariance parameters result from the unstructured blocks of . There is no matrix for this model.

The 17 quasi-Newton iterations are used to find the maximum likelihood estimates (Output 48.5.2).

The 44 matrix in Output 48.5.3 is the estimated unstructured covariance matrix. It is the estimate of the first block of , and the other 26 blocks all have the same estimate.

The “Covariance Parameter Estimates” table in Output 48.5.4 lists the 10 estimated covariance parameters in order; note their correspondence to the first block of displayed in Output 48.5.3. The parameter estimates are labeled according to their location in the block in the Cov Parm column, and all of these estimates are associated with Person as the subject effect.

The “Type III Tests of Fixed Effects” table in Output 48.5.5 displays Type III tests for all of the fixed effects. These tests are partial in the sense that they account for all of the other fixed effects in the model.

Since the different levels of the repeated effect represent different years, it is natural to try fitting a time series model to the data within each subject. To obtain time series structures in , you can replace TYPE=UN with TYPE=AR(1) to obtain the first-order autoregressive covariance matrices. For example, the statements to fit an AR(1) structure are as follows:

proc hpmixed data=pr;
   class Person Gender Time;
   model y = Gender Age Gender*Age;
   repeated Time / type=ar(1) sub=Person r;
run;

The estimated AR(1) structure covariance matrix of the first block of is shown in Output 48.5.6