PROBPLOT Statement: CAPABILITY Procedure

Dictionary of Options

The following entries provide detailed descriptions of options specific to the PROBPLOT statement. The notes Traditional Graphics, ODS Graphics, and Line Printer identify options that apply to traditional graphics, ODS Graphics output, and line printer plots, respectively. See Dictionary of Common Options: CAPABILITY Procedure for detailed descriptions of options common to all the plot statements.

ALPHA=value-list|EST

specifies values for a mandatory shape parameter $\alpha$ $(\alpha >0)$ for probability plots requested with the BETA, GAMMA, PARETO, and POWER options. A plot is created for each value specified. For examples, see the entries for the distribution options. If you specify ALPHA=EST, a maximum likelihood estimate is computed for $\alpha$ .

BETA(ALPHA=value-list|EST BETA=value-list|EST <beta-options>)

creates a beta probability plot for each combination of the shape parameters $\alpha$ and $\beta$ given by the mandatory ALPHA= and BETA= options. If you specify ALPHA=EST and BETA=EST, a plot is created based on maximum likelihood estimates for $\alpha$ and $\beta$ . In the following examples, the first PROBPLOT statement produces one plot, the second statement produces four plots, the third statement produces six plots, and the fourth statement produces one plot:

proc capability data=measures;
   probplot width / beta(alpha=2 beta=2);
   probplot width / beta(alpha=2 3 beta=1 2);
   probplot width / beta(alpha=2 to 3 beta=1 to 2 by 0.5);
   probplot width / beta(alpha=est beta=est);
run;

To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $B_{ \alpha \beta }^{-1} \left( \frac{ i - 0.375 }{ n + 0.25 } \right)$ , where $B_{ \alpha \beta }^{-1} ( \cdot )$ is the inverse normalized incomplete beta function, n is the number of nonmissing observations, and $\alpha$ and $\beta$ are the shape parameters of the beta distribution. The horizontal axis is scaled in percentile units.

The point pattern on the plot for ALPHA= $\alpha$ and BETA= $\beta$ tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are beta distributed with the specific density function

$p(x)=\left\{ \begin{array}{ll} \frac{(x - \theta )^{\alpha - 1} (\theta + \sigma - x)^{\beta - 1} }{B(\alpha ,\beta ) \sigma ^{(\alpha + \beta - 1)} } & \mbox{for $\theta < x < \theta + \sigma $} \\ 0 & \mbox{for $x \leq \theta $ or $x \geq \theta + \sigma $ } \end{array} \right.$

where $B(\alpha ,\beta ) = \frac{\Gamma (\alpha )\Gamma (\beta )}{\Gamma (\alpha +\beta )}$ and $\theta =$ lower threshold parameter $\sigma =$ scale parameter $(\sigma >0)$ $\alpha =$ first shape parameter $(\alpha >0)$ $\beta =$ second shape parameter $(\beta >0)$

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To obtain graphical estimates of $\alpha$ and $\beta$ , specify lists of values for the ALPHA= and BETA= options, and select the combination of $\alpha$ and $\beta$ that most nearly linearizes the point pattern.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the beta-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the beta-options THETA=EST and SIGMA=EST. Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot width / beta(alpha=2 beta=3 theta=4 sigma=5);
run;

Agreement between the reference line and the point pattern indicates that the beta distribution with parameters $\alpha$ , $\beta$ , $\theta _0$ and $\sigma _0$ is a good fit. You can specify the SCALE= option as an alias for the SIGMA= option and the THRESHOLD= option as an alias for the THETA= option.

BETA=value-list|EST

specifies values for the shape parameter $\beta$ $(\beta >0)$ for probability plots requested with the BETA distribution option. A plot is created for each value specified with the BETA= option. If you specify BETA=EST, a maximum likelihood estimate is computed for $\beta$ . For examples, see the preceding entry for the BETA option.

C=value(-list)|EST

specifies the shape parameter c (c > 0) for probability plots requested with the WEIBULL and WEIBULL2 options. You must specify C= as a Weibull-option with the WEIBULL option; in this situation it accepts a list of values, or if you specify C=EST, a maximum likelihood estimate is computed for c. You can optionally specify C=value or C=EST as a Weibull2-option with the WEIBULL2 option to request a distribution reference line; in this situation, you must also specify SIGMA=value or SIGMA=EST.

For example, the first PROBPLOT statement below creates three three-parameter Weibull plots corresponding to the shape parameters c = 1, c = 2, and c = 3. The second PROBPLOT statement creates a single three-parameter Weibull plot corresponding to an estimated value of c. The third PROBPLOT statement creates a single two-parameter Weibull plot with a distribution reference line corresponding to and $\sigma _0=3$ .

proc capability data=measures;
   probplot width / weibull(c=1 2 3);
   probplot width / weibull(c=est);
   probplot width / weibull2(c=2 sigma=3);
run;

CGRID=color

Traditional Graphicsspecifies the color for the grid lines requested by the GRID option.

EXPONENTIAL<(exponential-options)> EXP(<exponential-options>)

creates an exponential probability plot. To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $-\log \! \! \left(1-\frac{i-0.375}{n+0.25} \right)$ , where n is the number of nonmissing observations. The horizontal axis is scaled in percentile units.

The point pattern on the plot tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are exponentially distributed with the specific density function

$p( x )= \left\{ \begin{array}{ll} \frac{ 1 }{ \sigma } \exp \left( - \frac{ x - \theta }{ \sigma } \right) & \mbox{ for $ x \geq \theta $ } \\ 0 & \mbox{ for $ x < \theta $ } \end{array} \right.$

where $\theta$ is a threshold parameter, and $\sigma$ is a positive scale parameter.

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the exponential-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the exponential-options THETA=EST and SIGMA=EST. Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot width / exponential(theta=4 sigma=5);
run;

Agreement between the reference line and the point pattern indicates that the exponential distribution with parameters $\theta _0$ and $\sigma _0$ is a good fit. You can specify the SCALE= option as an alias for the SIGMA= option and the THRESHOLD= option as an alias for the THETA= option.

GAMMA(ALPHA=value-list|EST <gamma-options> )

creates a gamma probability plot for each value of the shape parameter $\alpha$ given by the mandatory ALPHA= option. If you specify ALPHA=EST, a plot is created based on a maximum likelihood estimate for $\alpha$ .

For example, the first PROBPLOT statement below creates three plots corresponding to $\alpha =0.4$ , $\alpha =0.5$ , and $\alpha =0.6$ . The second PROBPLOT statement creates a single plot.

proc capability data=measures;
   probplot width / gamma(alpha=0.4 to 0.6 by 0.2);
   probplot width / gamma(alpha=est);
run;

To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $G_{\alpha }^{-1} \left( \frac{ i - 0.375 }{ n + 0.25 } \right)$ , where $G_{\alpha }^{-1}(\cdot )$ is the inverse normalized incomplete gamma function, n is the number of nonmissing observations, and $\alpha$ is the shape parameter of the gamma distribution. The horizontal axis is scaled in percentile units.

The point pattern on the plot for ALPHA= $\alpha$ tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are gamma distributed with the specific density function

$p(x)= \left\{ \begin{array}{ll} \frac{1}{ \sigma \Gamma (\alpha ) } \left( \frac{ x - \theta }{ \sigma } \right) ^{\alpha - 1} \exp \left( - \frac{ x - \theta }{ \sigma } \right) & \mbox{ for $ x > \theta $ } \\ 0 & \mbox{ for $ x \leq \theta $ } \end{array} \right.$ where $\theta =$ threshold parameter $\sigma =$ scale parameter $(\sigma >0)$ $\alpha =$ shape parameter $(\alpha >0)$

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To obtain a graphical estimate of $\alpha$ , specify a list of values for the ALPHA= option, and select the value that most nearly linearizes the point pattern.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the gamma-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the gamma-options THETA=EST and SIGMA=EST. Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot width / gamma(alpha=2 theta=3 sigma=4);
run;

Agreement between the reference line and the point pattern indicates that the gamma distribution with parameters $\alpha$ , $\theta _0$ and $\sigma _0$ is a good fit. You can specify the SCALE= option as an alias for the SIGMA= option and the THRESHOLD= option as an alias for the THETA= option.

GRID

draws reference lines perpendicular to the percentile axis at major tick marks.

GRIDCHAR='character'

Line Printerspecifies the character used for the lines requested by the GRID option for a line printer plot. The default is the vertical bar (|).

GUMBEL(<Gumbel-options>)

creates a Gumbel probability plot. To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $-\log \left( -\log \left( \frac{ i - 0.375 }{ n + 0.25 } \right) \right)$ , where n is the number of nonmissing observations. The horizontal axis is scaled in percentile units.

The point pattern on the plot tends to be linear with intercept $\mu$ and slope $\sigma$ if the data are Gumbel distributed with the specific density function

$p(x) = \frac{e^{-(x-\mu )/\sigma }}{\sigma } \exp \left( -e^{-(x-\mu )/\sigma }\right)$

where $\mu$ is a location parameter and $\sigma$ is a positive scale parameter.

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\mu _0$ and $\sigma _0$ with the Gumbel-options MU= $\mu _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\mu _0$ and $\sigma _0$ with the Gumbel-options MU=EST and SIGMA=EST. Specify these options in parentheses following the GUMBEL option.

Agreement between the reference line and the point pattern indicates that the Gumbel distribution with parameters $\mu _0$ and $\sigma _0$ is a good fit.

LEGEND=name | NONE

Traditional Graphics specifies the name of a LEGEND statement describing the legend for specification limit reference lines and fitted curves. Specifying LEGEND=NONE is equivalent to specifying the NOLEGEND option.

LGRID=linetype

Traditional Graphics specifies the line type for the grid lines requested by the GRID option.

LOGNORMAL(SIGMA=value-list|EST <lognormal-options>) LNORM(SIGMA=value-list|EST <lognormal-options>)

creates a lognormal probability plot for each value of the shape parameter $\sigma$ given by the mandatory SIGMA= option or its alias, the SHAPE= option. If you specify SIGMA=EST, a plot is created based on a maximum likelihood estimate for $\sigma$ .

For example, the first PROBPLOT statement below produces two plots, and the second PROBPLOT statement produces a single plot:

proc capability data=measures;
   probplot width / lognormal(sigma=1.5 2.5 l=2);
   probplot width / lognormal(sigma=est);
run;

To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $\exp \! \! \left( \sigma \Phi ^{-1} \! \left( \frac{ i - 0.375 }{ n + 0.25 } \right) \right)$ , where $\Phi ^{-1}(\cdot )$ is the inverse standard cumulative normal distribution, n is the number of nonmissing observations, and $\sigma$ is the shape parameter of the lognormal distribution. The horizontal axis is scaled in percentile units.

The point pattern on the plot for SIGMA= $\sigma$ tends to be linear with intercept $\theta$ and slope $\exp (\zeta )$ if the data are lognormally distributed with the specific density function

$p(x) = \left\{ \begin{array}{ll} \frac{1}{ \sigma \sqrt {2 \pi }(x - \theta ) } \exp \left(-\frac{ (\log (x - \theta )- \zeta )^{2} }{2 \sigma ^{2} } \right) & \mbox{for $x > \theta $} \\ 0 & \mbox{for $x \leq \theta $} \end{array} \right.$ where $\theta =$ threshold parameter $\zeta =$ scale parameter $\sigma =$ shape parameter $(\sigma > 0)$

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To obtain a graphical estimate of $\sigma$ , specify a list of values for the SIGMA= option, and select the value that most nearly linearizes the point pattern.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\zeta _0$ with the lognormal-options THETA= $\theta _0$ and ZETA= $\zeta _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\zeta _0$ with the lognormal-options THETA=EST and ZETA=EST.

Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot width / lognormal(sigma=2 theta=3 zeta=0);
run;

Agreement between the reference line and the point pattern indicates that the lognormal distribution with parameters $\sigma$ , $\theta _0$ , and $\zeta _0$ is a good fit. See Example 5.20 for an example.

You can specify the THRESHOLD= option as an alias for the THETA= option and the SCALE= option as an alias for the ZETA= option.

MU=value|EST

specifies the mean $\mu _0$ for a probability plot requested with the GUMBEL and NORMAL options. If you specify MU=EST, $\mu _0$ is equal to the sample mean for the normal distribution. For the Gumbel distribution, a maximum likelihood estimate is calculated. See Example 5.19.

NADJ=value

specifies the adjustment value added to the sample size in the calculation of theoretical percentiles. The default is $\frac{1}{4}$ , as recommended by Blom (1958). Also refer to Chambers et al. (1983) for additional information.

NOLEGEND

suppresses legends for specification limits, fitted curves, distribution lines, and hidden observations.

NOLINELEGEND NOLINEL

suppresses the legend for the optional distribution reference line.

NOOBSLEGEND NOOBSL

Line Printersuppresses the legend that indicates the number of hidden observations.

NORMAL<(normal-options)> NORM<(normal-options)>

creates a normal probability plot. This is the default if you do not specify a distribution option. To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $\Phi ^{-1} \! \! \left( \frac{i- 0.375}{n+ 0.25} \right)$ , where $\Phi ^{-1}(\cdot )$ is the inverse cumulative standard normal distribution, and n is the number of nonmissing observations. The horizontal axis is scaled in percentile units.

The point pattern on the plot tends to be linear with intercept $\mu$ and slope $\sigma$ if the data are normally distributed with the specific

$p(x) = \begin{array}{ll} \frac{1}{\sigma \sqrt {2 \pi } } \exp \left( -\frac{(x - \mu )^2}{2 \sigma ^{2}} \right) & \mbox{for all \Mathtext{x}} \\ \end{array}$

where $\mu$ is the mean and $\sigma$ is the standard deviation ( $\sigma > 0$ ).

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\mu _0$ and $\sigma _0$ with the normal-options MU= $\mu _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\mu _0$ and $\sigma _0$ with the normal-options THETA=EST and SIGMA=EST; the estimates of $\mu _0$ and $\sigma _0$ are the sample mean and sample standard deviation.

Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot length / normal(mu=10 sigma=0.3);
   probplot length / normal(mu=est sigma=est);
run;

Agreement between the reference line and the point pattern indicates that the normal distribution with parameters $\mu _0$ and $\sigma _0$ is a good fit.

NOSPECLEGEND NOSPECL

suppresses the legend for specification limit reference lines.

PARETO(<Pareto-options>)

creates a generalized Pareto probability plot for each value of the shape parameter $\alpha$ given by the mandatory ALPHA= option. If you specify ALPHA=EST, a plot is created based on a maximum likelihood estimate for $\alpha$ .

To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $( 1 - ( 1 - \frac{ i - 0.375 }{ n + 0.25 } )^{\alpha } ) / \alpha$ ( $\alpha \neq 0$ ) or $-\log ( 1 - \frac{ i - 0.375 }{ n + 0.25 } )$ ( $\alpha = 0$ ), where n is the number of nonmissing observations and $\alpha$ is the shape parameter of the generalized Pareto distribution. The horizontal axis is scaled in percentile units.

The point pattern on the plot for ALPHA= $\alpha$ tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are generalized Pareto distributed with the specific density function

$p(x) = \left\{ \begin{array}{ll} \frac{1}{\sigma }{(1 - \alpha (x-\theta )/\sigma )}^{1/\alpha -1} & \mbox{if $ \alpha \neq 0$} \\ \frac{1}{\sigma }\exp (-(x-\theta )/\sigma ) & \mbox{if $ \alpha = 0$} \end{array} \right.$

where $\theta =$ threshold parameter $\sigma =$ scale parameter $(\sigma >0)$ $\alpha =$ shape parameter $(\alpha >0)$

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To obtain a graphical estimate of $\alpha$ , specify a list of values for the ALPHA= option, and select the value that most nearly linearizes the point pattern.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the Pareto-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the Pareto-options THETA=EST and SIGMA=EST. Specify these options in parentheses following the PARETO option.

Agreement between the reference line and the point pattern indicates that the generalized Pareto distribution with parameters $\alpha$ , $\theta _0$ , and $\sigma _0$ is a good fit.

PCTLMINOR

Traditional Graphicsrequests minor tick marks for the percentile axis. See Output 5.20.1 for an example.

PCTLORDER=value-list

specifies the tick mark values labeled on the theoretical percentile axis. Since the values are percentiles, the labels must be between 0 and 100, exclusive. The values must be listed in increasing order and must cover the plotted percentile range. Otherwise, a default list is used. For example, consider the following:

proc capability data=measures;
   probplot length / pctlorder=1 10 25 50 75 90 99;
run;

Note that the ORDER= option in the AXIS statement is not supported by the PROBPLOT statement.

POWER(<power-options>)

creates a power function probability plot for each value of the shape parameter $\alpha$ given by the mandatory ALPHA= option. If you specify ALPHA=EST, a plot is created based on a maximum likelihood estimate for $\alpha$ .

To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $B_{ \alpha (1) }^{-1} \left( \frac{ i - 0.375 }{ n + 0.25 } \right)$ , where $B_{ \alpha (1) }^{-1} ( \cdot )$ is the inverse normalized incomplete beta function, n is the number of nonmissing observations, $\alpha$ is one shape parameter of the beta distribution, and the second shape parameter, $\beta = 1$ . The horizontal axis is scaled in percentile units.

The point pattern on the plot for ALPHA= $\alpha$ tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are power function distributed with the specific density function

$p(x) = \left\{ \begin{array}{ll} \frac{\alpha }{\sigma }\left(\frac{x-\theta }{\sigma }\right)^{\alpha -1} & \mbox{for $\theta < x < \theta + \sigma $} \\ 0 & \mbox{for $x \leq \theta $ or $x \geq \theta + \sigma $ } \end{array} \right.$

where $\theta =$ threshold parameter $\sigma =$ scale parameter $(\sigma >0)$ $\alpha =$ shape parameter $(\alpha >0)$

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To obtain a graphical estimate of $\alpha$ , specify a list of values for the ALPHA= option, and select the value that most nearly linearizes the point pattern.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the power-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the power-options THETA=EST and SIGMA=EST. Specify these options in parentheses following the POWER option.

Agreement between the reference line and the point pattern indicates that the power function distribution with parameters $\alpha$ , $\theta _0$ , and $\sigma _0$ is a good fit.

PROBSYMBOL='character'

Line Printer specifies the character used to mark the points in a line printer plot. The default is the plus sign (+).

RANKADJ=value

specifies the adjustment value added to the ranks in the calculation of theoretical percentiles. The default is $-\frac{3}{8}$ , as recommended by Blom (1958). Also refer to Chambers et al. (1983) for additional information.

RAYLEIGH(<Rayleigh-options>)

creates a Rayleigh probability plot. To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $\sqrt {-2 \log \left(1-\frac{i-0.375}{n+0.25} \right)}$ , where n is the number of nonmissing observations. The horizontal axis is scaled in percentile units.

The point pattern on the plot tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are Rayleigh distributed with the specific density function

$p(x) = \left\{ \begin{array}{ll} \frac{x-\theta }{\sigma ^2}\exp (-(x-\theta )^2/(2\sigma ^2)) & \mbox{for $x \geq \theta $} \\ 0 & \mbox{for $x <\theta $} \end{array} \right.$

where $\theta$ is a threshold parameter, and $\sigma$ is a positive scale parameter.

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the Rayleigh-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the Rayleigh-options THETA=EST and SIGMA=EST. Specify these options in parentheses after the RAYLEIGH option.

Agreement between the reference line and the point pattern indicates that the Rayleigh distribution with parameters $\theta _0$ and $\sigma _0$ is a good fit.

ROTATE

switches the horizontal and vertical axes so that the theoretical percentiles are plotted vertically while the data are plotted horizontally. Regardless of whether the plot has been rotated, horizontal axis options (such as HAXIS=) still refer to the horizontal axis, and vertical axis options (such as VAXIS=) still refer to the vertical axis. All other options that depend on axis placement adjust to the rotated axes.

SIGMA=value-list|EST

specifies the value of the parameter $\sigma$ , where $\sigma >0$ . Alternatively, you can specify SIGMA=EST to request a maximum likelihood estimate for $\sigma _0$ . The interpretation and use of the SIGMA= option depend on the distribution option with which it is specified, as indicated by the following table.

Distribution Option	Use of the SIGMA= Option
BETA	THETA= $\theta _0$ and SIGMA= $\sigma _0$ request a distribution reference
EXPONENTIAL	line corresponding to $\theta _0$ and $\sigma _0$ .
GAMMA
PARETO
POWER
RAYLEIGH
WEIBULL
GUMBEL	MU= $\mu _0$ and SIGMA= $\sigma _0$ request a distribution reference line corresponding to $\mu _0$ and $\sigma _0$ .
LOGNORMAL	SIGMA= $\sigma _1 \ldots \sigma _ n$ requests n probability plots with shape parameters $\sigma _1 \ldots \sigma _ n$ . The SIGMA= option must be specified.
NORMAL	MU= $\mu _0$ and SIGMA= $\sigma _0$ request a distribution reference line corresponding to $\mu _0$ and $\sigma _0$ . SIGMA=EST requests a line with $\sigma _0$ equal to the sample standard deviation.
WEIBULL2	SIGMA= $\sigma _0$ and C= request a distribution reference line corresponding to $\sigma _0$ and .

In the following example, the first PROBPLOT statement requests a normal plot with a distribution reference line corresponding to $\mu _{0}=5$ and $\sigma _{0}=2$ , and the second PROBPLOT statement requests a lognormal plot with shape parameter $\sigma =3$ :

proc capability data=measures;
   probplot length / normal(mu=5 sigma=2);
   probplot width  / lognormal(sigma=3);
run;

SLOPE=value|EST

specifies the slope for a distribution reference line requested with the LOGNORMAL and WEIBULL2 options. The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

When you use the SLOPE= option with the LOGNORMAL option, you must also specify a threshold parameter value $\theta _0$ with the THETA= lognormal-option to request the line. The SLOPE= option is an alternative to the ZETA= lognormal-option for specifying $\zeta _0$ , since the slope is equal to $\exp (\zeta _0)$ .

When you use the SLOPE= option with the WEIBULL2 option, you must also specify a scale parameter value $\sigma _0$ with the SIGMA= Weibull2-option to request the line. The SLOPE= option is an alternative to the C= Weibull2-option for specifying , since the slope is equal to . See Location and Scale Parameters.

For example, the first and second PROBPLOT statements below produce the same set of probability plots as the third and fourth PROBPLOT statements:

proc capability data=measures;
   probplot width / lognormal(sigma=2 theta=0 zeta=0);
   probplot width / weibull2(sigma=2 theta=0 c=0.25);
   probplot width / lognormal(sigma=2 theta=0 slope=1);
   probplot width / weibull2(sigma=2 theta=0 slope=4);
run;

SQUARE

Traditional GraphicsODS Graphicsdisplays the probability plot in a square frame. For an example, see Output 5.20.1. The default is a rectangular frame.

SYMBOL='character'

Line Printer specifies the character used to display the distribution reference line in a line printer plot. The default character is the first letter of the distribution option keyword.

THETA=value|EST THRESHOLD=value

specifies the lower threshold parameter $\theta$ for probability plots requested with the BETA, EXPONENTIAL, GAMMA, LOGNORMAL, PARETO, POWER, RAYLEIGH, WEIBULL, and WEIBULL2 options. When used with the WEIBULL2 option, the THETA= option specifies the known lower threshold $\theta _0$ , for which the default is 0. When used with the other distribution options, the THETA= option specifies $\theta _0$ for a distribution reference line; alternatively in this situation, you can specify THETA=EST to request a maximum likelihood estimate for $\theta _0$ . To request the line, you must also specify a scale parameter. See Output 5.20.1 for an example of the THETA= option with a lognormal probability plot.

WEIBULL(C=value-list|EST <Weibull-options>) WEIB(C=value-list <Weibull-options>)

creates a three-parameter Weibull probability plot for each value of the shape parameter c given by the mandatory C= option or its alias, the SHAPE= option. If you specify C=EST, a plot is created based on a maximum likelihood estimate for c. In the following example, the first PROBPLOT statement creates four plots, and the second PROBPLOT statement creates a single plot:

proc capability data=measures;
   probplot width / weibull(c=1.8 to 2.4 by 0.2 w=2);
   probplot width / weibull(c=est);
run;

To create the plot, the observations are ordered from smallest to largest, and the ith ordered observation is plotted against the quantile $\left( -\log \! \left(1-\frac{i-0.375}{n+0.25} \right) \right)^{\frac{1}{c}}$ , where n is the number of nonmissing observations, and c is the Weibull distribution shape parameter. The horizontal axis is scaled in percentile units.

The point pattern on the plot for C=c tends to be linear with intercept $\theta$ and slope $\sigma$ if the data are Weibull distributed with the specific density function

$p(x)= \left\{ \begin{array}{ll} \frac{c}{\sigma } \left( \frac{x - \theta }{\sigma } \right)^{c - 1} \exp \left( - \left( \frac{x - \theta }{\sigma } \right)^{c} \right) & \mbox{ for $x > \theta $ } \\ 0 & \mbox{ for $x \leq \theta $ } \end{array} \right.$ where $\theta =$ threshold parameter $\sigma =$ scale parameter $(\sigma >0)$ shape parameter

The intercept and slope are based on the quantile scale for the horizontal axis, which is displayed on a Q-Q plot; see QQPLOT Statement: CAPABILITY Procedure.

To obtain a graphical estimate of c, specify a list of values for the C= option, and select the value that most nearly linearizes the point pattern.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\theta _0$ and $\sigma _0$ with the Weibull-options THETA= $\theta _0$ and SIGMA= $\sigma _0$ . Alternatively, you can add a line corresponding to estimated values of $\theta _0$ and $\sigma _0$ with the Weibull-options THETA=EST and SIGMA=EST. Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot width / weibull(c=2 theta=3 sigma=4);
run;

Agreement between the reference line and the point pattern indicates that the Weibull distribution with parameters c, $\theta _0$ , and $\sigma _0$ is a good fit. You can specify the SCALE= option as an alias for the SIGMA= option and the THRESHOLD= option as an alias for the THETA= option.

WEIBULL2<(Weibull2-options)> W2<(Weibull2-options)>

creates a two-parameter Weibull probability plot. You should use the WEIBULL2 option when your data have a known lower threshold $\theta _0$ . You can specify the threshold value $\theta _0$ with the THETA= Weibull2-option or its alias, the THRESHOLD= Weibull2-option. The default is $\theta _0 = 0$ .

To create the plot, the observations are ordered from smallest to largest, and the log of the shifted ith ordered observation $x_{(i)}$ , denoted by $\log (x_{(i)} - \theta _0 )$ , is plotted against the quantile $\log \! \! \left(-\log \! \left(1-\frac{i-0.375}{n+0.25} \right) \right)$ , where n is the number of nonmissing observations. The horizontal axis is scaled in percentile units. Note that the C= shape parameter option is not mandatory with the WEIBULL2 option.

The point pattern on the plot for THETA= $\theta _0$ tends to be linear with intercept $\log (\sigma )$ and slope $\frac{1}{c}$ if the data are Weibull distributed with the specific density function

$p(x) = \left\{ \begin{array}{ll} \frac{c}{\sigma } \left( \frac{x - \theta _0}{\sigma } \right)^{c - 1} \exp \left( - \left( \frac{x - \theta _0}{\sigma } \right)^{c} \right) & \mbox{ for $x > \theta _0$ } \\ 0 & \mbox{ for $x \leq \theta _0$ } \end{array} \right.$ where $\theta _0 =$ known lower threshold $\sigma =$ scale parameter $(\sigma >0)$ shape parameter

An advantage of the two-parameter Weibull plot over the three-parameter Weibull plot is that the parameters c and $\sigma$ can be estimated from the slope and intercept of the point pattern. A disadvantage is that the two-parameter Weibull distribution applies only in situations where the threshold parameter is known.

To assess the point pattern, you can add a diagonal distribution reference line corresponding to $\sigma _0$ and ${c_0}$ with the Weibull2-options SIGMA= $\sigma _0$ and C= ${c_0}$ . Alternatively, you can add a distribution reference line corresponding to estimated values of $\sigma _0$ and ${c_0}$ with the Weibull2-options SIGMA=EST and C=EST. Specify these options in parentheses, as in the following example:

proc capability data=measures;
   probplot width / weibull2(theta=3 sigma=4 c=2);
run;

Agreement between the distribution reference line and the point pattern indicates that the Weibull distribution with parameters , $\theta _0$ and $\sigma _0$ is a good fit. You can specify the SCALE= option as an alias for the SIGMA= option and the SHAPE= option as an alias for the C= option.

WGRID=n

Traditional Graphicsspecifies the width of the grid lines requested with the GRID option. If you use the WGRID= option, you do not need to specify the GRID option.

ZETA=value|EST

specifies a value for the scale parameter $\zeta$ for lognormal probability plots requested with the LOGNORMAL option. Specify THETA= $\theta _0$ and ZETA= $\zeta _0$ to request a distribution reference line with intercept $\theta _0$ and slope $\exp (\zeta _0)$ . See Output 5.20.1 for an example.