The RELIABILITY Procedure

Meeker and Escobar (1998, p. 447) analyzed data from an accelerated test on the lifetimes of glass capacitors as a function of operating voltage and temperature. The following SAS statements create a SAS data set containing the data. There are four lifetimes for each of eight combinations and four censored observations after the fourth failure for each combination:

data glass;
   input Temp Voltage @;
   do i = 1 to 4;
      cen = 0;
      input Hours @; output;      
   end;
   do i = 1 to 4; 
      cen = 1;
      output; 
   end;
   datalines;
170 200  439  904  1092  1105
170 250  572  690   904  1090
170 300  315  315   439   628
170 350  258  258   347   588
180 200  959 1065  1065  1087
180 250  216  315   455   473
180 300  241  315   332   380
180 350  241  241   435   455
;

The following statements analyze the capacitor data. The MODEL statement fits a regression model with Temp and Voltage as independent variables. Parameter estimates from the fitted regression model are shown in Figure 16.24. An interaction term between Temp and Voltage is included. The PPLOT statement creates a Weibull probability plot shown in Figure 16.25 with all temperature-voltage combinations overlaid on the same plot. The regression model fit is also plotted. The RPLOT statement creates the plot shown in Figure 16.26 of the data and Weibull distribution percentiles from the regression model as a function of voltage for values of temperature of 150, 170, and 180:

proc reliability data = glass;                                                               
   distribution Weibull;                                                                     
   model Hours*cen(1) = temp voltage temp * voltage;                                                        
   pplot Hours*cen(1) = ( temp voltage ) / fit = model                                       
                                           overlay                                           
                                           noconf                                            
                                           lupper = 2000;
run;                                                                                      

proc reliability data = glass;                                                
   distribution Weibull;                                                      
   model Hours*cen(1) = temp voltage temp * voltage;                          
   rplot Hours*cen(1) = voltage / fit = regression(temp = 150, 170, 180)
                                  plotfit;                        
run;                                                                          

Figure 16.25: Probability Plot for Glass Capacitor Regression Model

Figure 16.26: Plot of Data and Fitted Weibull Percentiles for Glass Capacitor Regression Model