IRCHART Statement: SHEWHART Procedure

Note: See Individual Measurement and Moving Range Charts in the SAS/QC Sample Library.

You can save the control limits for individual measurements and moving range charts in a SAS data set; this enables you to apply the control limits to future data (see Reading Preestablished Control Limits) or modify the limits with a DATA step program.

The following statements read the diameter measurements from the data set Jets (see Creating Individual Measurements and Moving Range Charts) and save the control limits displayed in Figure 17.27 in a data set named Jetlim:

proc shewhart data=Jets;
   irchart Diam*Engine / outlimits = Jetlim
                         nochart;
run;

The OUTLIMITS= option names the data set containing the control limits, and the NOCHART option suppresses the display of the charts. The data set Jetlim is listed in Figure 17.30.

The data set Jetlim contains one observation with the limits for process Diam. The variables _LCLI_ and _UCLI_ contain the control limits for the individual measurements, and the variable _MEAN_ contains the central line. The variables _LCLR_ and _UCLR_ contain the control limits for the moving ranges, and the variable _R_ contains the central line. The value of _MEAN_ is an estimate of the process mean, and the value of _STDDEV_ is an estimate of the process standard deviation . The value of _LIMITN_ is the number of consecutive measurements used to compute the moving ranges, and the value of _SIGMAS_ is the multiple of associated with the control limits. The variables _VAR_ and _SUBGRP_ are bookkeeping variables that save the process and subgroup-variable. The variable _TYPE_ is a bookkeeping variable that indicates whether the values of _MEAN_ and _STDDEV_ are estimates or standard values. For more information, see OUTLIMITS= Data Set.

You can create an output data set containing both control limits and summary statistics with the OUTTABLE= option, as illustrated by the following statements:

proc shewhart data=Jets;
   irchart Diam*Engine / outtable=Jtable
                         nochart;
run;

The data set Jtable is listed in Figure 17.31.

This data set contains one observation for each subgroup. The variables _SUBI_ and _SUBR_ contain the individual measurements and moving ranges. The variables _LCLI_ and _UCLI_ contain the lower and upper control limits for the individual measurements chart, and the variables _LCLR_ and _UCLR_ contain the lower and upper control limits for the moving range chart. The variable _MEAN_ contains the central line of the individual measurements chart, and the variable _R_ contains the central line of the moving range chart. The variables _VAR_ and Engine contain the process name and values of the subgroup-variable, respectively. For more information, see OUTTABLE= Data Set.

An OUTTABLE= data set can be read later as a TABLE= data set. For example, the following statements read Jtable and display charts (not shown here) identical to those in Figure 17.27:

title 'Individual Measurements and Moving Range Control Charts';
title2 'Jet Engine Diameters (cm)';
proc shewhart table=Jtable;
   irchart Diam*Engine;
run;

Because the SHEWHART procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized control charts (see Specialized Control Charts: SHEWHART Procedure).

For more information, see TABLE= Data Set.