The MIANALYZE Procedure

This example creates data sets to contain parameter estimates that are computed by a nominal logistic regression analysis for a set of imputed data sets. These estimates are then combined to generate valid statistical inferences about the model parameters.

The following statements use PROC LOGISTIC to generate the parameter estimates and covariance matrix for each imputed data set:

proc logistic data=outfish3;
   class Species;
   model Species= Length Width / link=glogit covb;
   by _Imputation_;
   ods output ParameterEstimates=lgsparms
              CovB=lgscovb;
run;

The following statements display (in Output 62.9.1) the output logistic regression coefficients from PROC LOGISTIC for the first two imputed data sets:

proc print data=lgsparms (obs=12);
   title 'LOGISTIC Model Coefficients (First Two Imputations)';
run;

The following statements display the covariance matrices that are associated with parameter estimates derived from the first two imputations in Output 62.9.2:

proc print data=lgscovb (obs=12);
   title 'LOGISTIC Model Covariance Matrices (First Two Imputations)';
run;

The following statements use the MIANALYZE procedure with the input PARMS= and COVB= data sets:

proc mianalyze parms(link=glogit)=lgsparms
               covb(effectvar=stacking)=lgscovb
               mult;
   modeleffects Intercept Length Width;
run;

The “Variance Information” table in Output 62.9.3 displays the between-imputation, within-imputation, and total variances for combining complete-data inferences.

The “Parameter Estimates” table in Output 62.9.4 displays the combined parameter estimates and their associated standard errors.

The “Multivariate Inference” table in Output 62.9.5 displays multivariate inference for the parameters assuming proportionality of the between-imputation and within-imputation covariance matrices.