The MIANALYZE Procedure

This example illustrates sensitivity analysis in multiple imputation under the MNAR assumption by searching for a tipping point that reverses the study conclusion.

Suppose that a pharmaceutical company is conducting a clinical trial to test the efficacy of a new drug. The trial consists of two groups of equally allocated patients: a treatment group that receives the new drug and a placebo control group. The variable Trt is an indicator variable, with a value of 1 for patients in the treatment group and a value of 0 for patients in the control group. The variable Y0 is the baseline efficacy score, and the variable Y1 is the efficacy score at a follow-up visit.

If the data set does not contain any missing values, then a regression model such as

can be used to test the efficacy of the treatment effect.

Suppose that the variables Trt and Y0 are fully observed and the variable Y1 contains missing values in both the treatment and control groups. Now suppose the data set Mono2 contains the data from a trial that have missing values in Y1. Output 62.13.1 lists the first 10 observations.

Multiple imputation often assumes that missing values are missing at random (MAR), and the following statements use the MI procedure to impute missing values under this assumption:

proc mi data=Mono2 seed=14823 nimpute=10 out=outmi;
   class Trt;
   monotone reg;
   var Trt y0 y1;
run;

The following statements generate regression coefficients for each of the 10 imputed data sets:

ods listing close;
proc reg data=outmi;
   model y1= Trt y0;
   by  _Imputation_;
   ods output parameterestimates=regparms;
run;

The following statements combine the 10 sets of regression coefficients:

ods listing;
proc mianalyze parms=regparms;
   modeleffects Trt;
run;

The “Parameter Estimates” table in Output 62.13.2 displays a combined estimate and standard error for the regression coefficient for Trt. The table displays a 95% confidence interval (0.2865, 1.2261), which does not contain 0. The table also shows a t test statistic of 3.19, with the associated p-value 0.0019 for the test that the regression coefficient is equal to 0.

The conclusion in Output 62.13.2 is based on the MAR assumption. But if it is plausible that, for the treatment group, the distribution of missing Y1 responses has a lower expected value than that of the corresponding distribution of the observed Y1 responses, the conclusion under the MAR assumption should be examined.

The following macro generates multiple imputed data sets, with a specified sequence of shift parameters that adjust the imputed values for observations in the treatment group (TRT=1):

/*----------------------------------------------------------------*/
/*--- Generate imputed data set for specified shift parameters ---*/
/*--- data= input data set                                     ---*/
/*--- smin= min shift parameter                                ---*/
/*--- smax= max shift parameter                                ---*/
/*--- sinc= increment of the shift parameter                   ---*/
/*--- out=  output imputed data set                            ---*/
/*----------------------------------------------------------------*/
%macro midata( data=, smin=, smax=, sinc=, out=);

data &out;
   set _null_;
run;

/*------------ # of shift values ------------*/
%let ncase= %sysevalf( (&smax-&smin)/&sinc, ceil );

/*------- Imputed data for each shift -------*/
%do jc=0 %to &ncase;
   %let sj= %sysevalf( &smin + &jc * &sinc);

   proc mi data=&data seed=14823 nimpute=10 out=outmi;
      class Trt;
      monotone reg;
      mnar adjust( y1 / shift=&sj  adjustobs=(Trt='1') );
      var Trt y0 y1;
   run;

   data outmi;
      set outmi;
      Shift= &sj;
   run;

   data &out;
      set &out outmi;
   run;

%end;
%mend midata;

Assume that the tipping point that reverses the study conclusion is between –2 and 0. The following statements generate 10 imputed data sets for each of the shift parameters –2.0, –1.8, …, 0.

ods listing close;
%midata( data=Mono2, smin=-2, smax=0, sinc=0.2, out=out1);

The following statements perform regression tests on the imputed data sets and combine results for each shift parameter:

/*------- Reg tests on imputed data sets -------*/
/*------- for each shift parameter -------------*/
proc reg data=out1;
   model y1= Trt y0;
   by  Shift _Imputation_;
   ods output parameterestimates=regparms;
run;

/*------ Combine reg results -------*/
proc mianalyze parms=regparms;
   modeleffects Trt;
   by  Shift;
   ods output parameterestimates=miparm1;
run;

The following statements display the p-values that are associated with the shift parameters:

ods listing;
proc print label data=miparm1;
   var Shift Probt;
   title 'P-values for Shift Parameters';
   label Probt='Pr > |t|';
   format Probt 8.4;
run;

For a two-sided Type I error level of 0.05, the tipping point for the shift parameter is between –1.4 and –1.2. The following statements generate multiple imputed data sets, with shift parameters –1.40, –1.39, …, –1.20.

ods listing close;
%midata( data=Mono2, smin=-1.4, smax=-1.2, sinc=0.01, out=out2);

The following statements perform regression tests on the imputed data sets and combine results for each shift parameter:

/*------- Reg tests on imputed data sets -------*/
/*------- for each shift parameter -------------*/
proc reg data=out2;
   model y1= Trt y0;
   by  Shift _Imputation_;
   ods output parameterestimates=regparms;
run;

/*------ Combine reg results -------*/
proc mianalyze parms=regparms;
   modeleffects Trt;
   by  Shift;
   ods output parameterestimates=miparm2;
run;

The following statements display the p-values that are associated with the shift parameters:

ods listing;
proc print label data=miparm2;
   var Shift Probt;
   title 'P-values for Shift Parameters';
   label Probt='Pr > |t|';
   format Probt 8.4;
run;

The study conclusion under MAR is reversed when the shift parameter is –1.31. Thus, if this shift parameter –1.31 is plausible, the conclusion under MAR is questionable.