The SEQDESIGN Procedure

This example illustrates sample size computation for survival data when the accrual is not uniform and when the data contain individual loss to follow-up.

Following the derivations in Example 87.14, the following statements invoke the SEQDESIGN procedure for sample size computation with exponential accrual and individual loss to follow-up:

proc seqdesign;
   OBrienFleming: design nstages=4 method=obf
                  ;
   samplesize model=twosamplesurvival
                    ( nullhazard=0.03466
                      hazard=0.01733
                      accrual=exp(parm=-0.1)
                      loss=exp(hazard=0.05)
                      acctime=20);
run;

The SAMPLESIZE statement derives required sample sizes for the test. The MODEL=TWOSAMPLESURVIVAL option specifies a log-rank test to compare two survival distributions for the treatment effect. The NULLHAZARD=0.03466 option specifies null hazard rates for the two groups under the null hypothesis, and the HAZARD=0.01733 option specifies the hazard rate for the first group under the alternative hypothesis.

The ACCTIME= option specifies the accrual time , and the ACCRUAL=EXP(POWER=–0.1) option specifies that the individual accrual be truncated exponential with a scaled power parameter . That is, the truncated exponential accrual has a power parameter in the accrual time . The LOSS=EXP(HAZARD=0.05) option specifies an exponential loss function with a hazard rate . For a detailed derivation of these required sample sizes, see the section Test for Two Survival Distributions with a Log-Rank Test.

The “Design Information” table in Output 87.15.1 displays design specifications and the derived maximum information.

The “Boundary Information” table in Output 87.15.2 displays information level, alternative reference, and boundary values.

The “Sample Size Summary” table in Output 87.15.3 displays parameters for the sample size computation. Because the ACCNOBS= option is not specified along with the ACCTIME= option, the minimum and maximum sample sizes are derived.

With the minimum and maximum sample sizes of 269 and 553, respectively, the ACCNOBS=360 option specifies an accrual sample size of 360 for the trial.

proc seqdesign;
   OBrienFleming: design nstages=4
                  method=obf
                  ;
   samplesize model=twosamplesurvival
                    ( nullhazard=0.03466
                      hazard=0.01733
                      accrual=exp(parm=-0.1)
                      loss=exp(hazard=0.05)
                      acctime=20 accnobs=360 );
run;

With the specified accrual sample size and accrual time, the “Sample Size Summary” table in Output 87.15.4 displays the follow-up time and maximum sample size with the specified accrual time. When you specify the CEILING=TIME option (which is the default), the required times at the stages are rounded up to integers for additional statistics, and the table also displays the follow-up time and total time that correspond to these ceiling times at the stages.

The “Number of Events (D) and Sample Sizes (N)” table in Output 87.15.5 displays the required time at each stage, in both fractional and integer numbers. The derived times under the heading “Fractional Time” are not integers. These times are rounded up to integers under the heading “Ceiling Time.” The table also displays the numbers of events and sample sizes at each stage.

Alternatively, you can specify the CEILING=N option in the SAMPLESIZE statement as follows to derive additional sample size information with ceiling sample sizes at each stage:

proc seqdesign;
   OBrienFleming: design nstages=4
                  method=obf
                  ;
   samplesize model=twosamplesurvival
                    ( nullhazard=0.03466
                      hazard=0.01733
                      accrual=exp(parm=-0.1)
                      loss=exp(hazard=0.05)
                      acctime=20 accnobs=360
                      ceiling=n);
run;

When you specify CEILING=N, the required sample sizes at the stages are rounded up to integers for additional statistics, and the “Sample Size Summary” table in Output 87.15.6 also displays the accrual time, follow-up time, and maximum sample size that correspond to these ceiling sample sizes.

The “Number of Events (D) and Sample Sizes (N)” table in Output 87.15.7 displays the required sample sizes at each stage, in both fractional and integer numbers. The derived numbers under the heading “Fractional N” are not integers. These numbers are rounded up to integers to match the sample size allocation under the heading “Ceiling N (Matched).” The table also displays the numbers of events and time at each stage.