The MIANALYZE Procedure

This example illustrates sensitivity analysis in multiple imputation under the MNAR assumption by creating control-based pattern imputation.

Suppose that a pharmaceutical company is conducting a clinical trial to test the efficacy of a new drug. The trial consists of two groups of equally allocated patients: a treatment group that receives the new drug and a placebo control group. The variable Trt is an indicator variable, with a value of 1 for patients in the treatment group and a value of 0 for patients in the control group. The variable Y0 is the baseline efficacy score, and the variable Y1 is the efficacy score at a follow-up visit.

If the data set does not contain any missing values, then a regression model such as

can be used to test the the treatment effect.

Suppose that the variables Trt and Y0 are fully observed and the variable Y1 contains missing values in both the treatment and control groups, as shown in Table 64.4.

Suppose the data set Mono1 contains the data from the trial that have missing values in Y1. Output 64.12.1 lists the first 10 observations.

Multiple imputation often assumes that missing values are missing at random (MAR), and the following statements use the MI procedure to impute missing values under this assumption:

proc mi data=Mono1 seed=14823 nimpute=10 out=outex12a;
   class Trt;
   monotone reg;
   var Trt y0 y1;
run;

The following statements generate regression coefficients for each of the 10 imputed data sets:

proc reg data=outex12a;
   model y1= Trt y0;
   by  _Imputation_;
   ods output parameterestimates=regparms;
run;

The following statements combine the 10 sets of regression coefficients:

proc mianalyze parms=regparms;
   modeleffects Trt;
run;

The "Parameter Estimates" table in Output 64.12.2 displays a combined estimate and standard error for the regression coefficient for Trt. The table shows a t test statistic of 3.37, with the associated p-value 0.0011 for the test that the regression coefficient is equal to 0.

The conclusion in Output 64.12.2 is based on the MAR assumption. But if missing Y1 values for individuals in the treatment group imply that these individuals no longer receive the treatment, then it is reasonable to assume that the conditional distribution of Y1, given Y0 for individuals who have missing Y1 values in the treatment group, is similar to the corresponding distribution of individuals in the control group.

Ratitch and O’Kelly (2011) describe an implementation of the pattern-mixture model approach that uses a control-based pattern imputation. That is, an imputation model for the missing observations in the treatment group is constructed not from the observed data in the treatment group but rather from the observed data in the control group. This model is also the imputation model that is used to impute missing observations in the control group.

The following statements implement the control-based pattern imputation:

proc mi data=Mono1 seed=14823 nimpute=10 out=outex12b;
   class Trt;
   monotone reg;
   mnar model( y1 /modelobs=(Trt='0'));
   var y0 y1;
run;

The MNAR statement imputes missing values for scenarios under the MNAR assumption. The MODEL option specifies that only observations where TRT=0 are used to derive the imputation model for the variable Y1. Thus, Y0 and Y1 (but not Trt) are specified in the VAR list.

The following statements generate regression coefficients for each of the 10 imputed data sets:

proc reg data=outex12b;
   model y1= Trt y0;
   by _Imputation_;
   ods output parameterestimates=regparms;
run;

The following statements combine the 10 sets of regression coefficients:

proc mianalyze parms=regparms;
   modeleffects Trt;
run;

The "Parameter Estimates" table in Output 64.12.3 shows a t test statistic of 2.24, with the p-value 0.0292 for the test that the parameter is equal to 0. Thus, for a two-sided Type I error level of 0.05, the significance of the treatment effect is not reversed by control-based pattern imputation.